Index / Map / last update: Oct 2007
Originally, I was calling my area the "Cosmic Encounter realms". It's now the "Cosmic Encounter Realm". A subtle difference.
@open down;d;enter platform;stand on platform;step on platform;
step onto platform;board platform : #8856
@desc #8865 = This floating platform takes intrepid explorers down to
the Cosmic Encounter Realm below.
@succ #8865 = @tell("%#","You step onto the floating platform.
Hidden mechanisms begin to hum, and the platform descends
into the long shaft below. After a few minutes, you arrive at a
spaceport lobby. You disembark.");
@tell("8796","[**CE**] A small voice whispers in your ear, \"%n just
entered the CE Realm.\"");
@osucc #8865 = steps onto the floating platform, which promptly descends
with %o into the shaft. Moments later, the platform returns, empty.
@fail #8865 = You step onto the floating platform. A pleasant female voice
says, "We are sorry. This platform is temporarily out of service."
Disappointed, you step off of the platform.
@ofail #8865 = steps onto the floating platform. A female voice says
"We are sorry. This platform is temporarily out of service."
%n steps off the platform.
@odrop #8865 = descends into the lobby via the floating platform.
%n steps off the platform.
@drop #8865 = "Welcome to the Cosmic Encounter Realm," says an unseen
female voice. "You are our honored guest. Don't forget to read the
leaflet in the mailbox!"
@field #8865 = exitto: to the Cosmic Encounter Realm
Originally called: "Cosmic Encounter Spaceport Lobby". I later decided that this ungainly room name could be shortened, assuming that the term "Cosmic Encounter" would to mentioned often enough elsewhere so that this particular jackhammer of exposition could be softened.
@dig Spaceport Lobby
@field #8856 = each_turn : @call(8905,"playsong")
@field #8856 = exit_0 : 8911
@field #8856 = exit_1 : 8994
@field #8856 = exit_2 : 10753
@field #8856 = exit_3 : 8894
@field #8856 = nexits : 4
@zone #8856 = #10719
@field #8856 = listen : @call(8905,"listen")
@desc #8856 = @tell("%#","The lobby is not only the entrance/exit point
to the Cosmic Encounter Realm, but also the hub of a major spaceport in
the vicinity of the dread Warp. The curious traveller can explore strange
new worlds, meet exotic aliens, solve a puzzle or two, or just play
\"tourist\". Come in and have fun!"); @call(10633,"each_turn");
@create onyx desk;onyx;desk;od
@ofail #8890 = tries to take the onyx desk, but it's obviously too heavy to
move.
@fail #8890 = @tell("%#","Sorry, but the onyx desk is far too heavy to move.
There isn't even a decent place to get a grip on it.");
@call(10633,"each_turn");
@field #8890 = search : @tell("%#","Behind the desk you find a speaker
switch."); @call(10633,"each_turn");
@lock #8890 = #-1
@zone #8890 = #10719
@desc #8890 = @tell("%#","A large block of black onyx serves as the
information desk for the lobby. It hardly seems practical. There is a
guestbook on the desk."); @call(10633,"each_turn");
@create speaker switch;speaker;switch
@set #10421 = dark
@field #10421 = turnoff : @tell("%#","You turn off the hidden speakers.");
@setfield("%!","setting","off"); @call(10633,"each_turn");
@field #10421 = turnon : @tell("%#","You turn on the hidden speakers.");
@setfield("%!","setting","on"); @call(10633,"each_turn");
@fail #10421 = @tell("%#","The speaker switch is part of the onyx desk.");
@call(10633,"each_turn");
@field #10421 = push : @switch(@getfield("%!","setting"),"on",
@call("%!","turnoff"),@call("%!","turnon"));
@lock #10421 = #-1
@field #10421 = setting : on
@desc #10421 = @tell("%#",@print("It's a small switch to turn on and off
the hidden speakers. The switch is currently turned ",
@getfield("%!","setting"), ".")); @call(10633,"each_turn");
Just a little thank you to Jota here, since under normal circumstances I would've only been able to get an apartment in Edifice Towers.
@create bronze plaque;bronze;plaque;bp
@ofail #9594 = tries to rip the bronze plaque off the wall, but fails to do
so.
@fail #9594 = @tell("%#","The bronze plaque is affixed to the wall. You
can't have it."); @call(10633,"each_turn");
@lock #9594 = #-1
@zone #9594 = #10719
@desc #9594 = @tell("%#","The bronze plaque reads: \"Thanks to Jota for
letting me build down here! -- DavidW\""); @call(10633,"each_turn");
Since creating the guestbook, I've realized that this is a particularly newbie thing to do but what the heck. The guestbook stays. I reserve the right to edit out dumb or test-type comments, though.
@create guestbook;guest book;book;gb @set #9598 = book @lock #9598 = #-1 @zone #9598 = #10719 @desc book = Welcome! This guestbook is here for guests to the Cosmic Encounter Realm to sign and add their comments.
One of my first visitors, Jearl, walked off with the ordinary iron key, which is a primo item needed to solve the master puzzle. Yes, the CE Realm has a puzzle or two to solve. So, insert one reset button which finds everything and puts it all back. TODO: It isn't clever enough to check that nobody else is in the *middle* of the realm, solving puzzles, though.
@create reset button;reset;rb;button
// 7 comic books
@field #10290 = it_zot : 9889
@field #10290 = it_invisibles : 10941
@field #10290 = it_godot : 10948
@field #10290 = it_totb : 10199
@field #10290 = it_sandman : 10969
@field #10290 = it_topten : 10939
@field #10290 = it_comic_powerpack : 10789
// 4 id cards
@field #10290 = it_idcard : 10362
@field #10290 = it_idcard2 : 11163
@field #10290 = it_idcard3 : 11164
@field #10290 = it_idcard4 : 11165
// 4 scrolls
@field #10290 = it_vaxum : 10699
@field #10290 = it_rezrov : 10694
@field #10290 = it_izyuk : 10698
@field #10290 = it_frotz : 10700
// lucre
@field #10290 = it_lucre_dusty : 10710
@field #10290 = it_lucre_filthy : 10717
@field #10290 = it_lucre_tarnished : 11729
@field #10290 = it_smudgedl : 10713
@field #10290 = it_grungyl : 10715
@field #10290 = it_dentedl : 10716
@field #10290 = it_shinyl : 10711
@field #10290 = it_dirtyl : 10712
@field #10290 = it_grimyl : 10714
// stuff from Gas Giant
@field #10290 = it_apple : 10475
@field #10290 = it_wand : 10304
@field #10290 = it_spear : 10303
@field #10290 = it_twinks : 10287
@field #10290 = it_progcard : 10164
@field #10290 = it_tpods : 10297
@field #10290 = it_chips : 10288
@field #10290 = it_hoops : 10286
@field #10290 = it_mpods : 10289
@field #10290 = it_scooper : 10305
@field #10290 = it_slats : 10285
// other
@field #10290 = it_pstick : 9622
@field #10290 = it_farac : 9883
@field #10290 = it_food : 10090
@field #10290 = it_key : 9862
@field #10290 = it_warpdoor : 9635
@field #10290 = it_leaflet : 9908
@field #10290 = it_spoiledegg : 11236
@field #10290 = it_saladshooter : 11373
@field #10290 = it_earmuffs : 781
@lock #10290 = #-1
@field #10290 = push : @tell("%#","You push the reset button. KA-CHUNK!");
@tellroom(@location("%#"),"%#","%n pushes the reset button. KA-CHUNK!");
@fieldloop("%!","it_",@call("%v","reset"));
@zone #10290 = #10719
@desc #10290 = @tell("%#","Push the reset button to put everything back
into place within the CE Realm."); @call(10633,"each_turn");
A private function, to generate the reset button's code. All this does it concatenate all the individual reset code associated with each object into one long code string. The reset code was split up to keep its maintenance within the realm of reason. Normally, I'd just @call each snippet of code, but there's a limit of 64 @call()s per action. So metareset was written to get around the limit.
@action metareset;meta-reset = #10290 : nowhere
@set #11329 = dark
@lock #11329 = me
@succ #11329 =
// make sure all the reset code snippets end in semi-colons.
@fieldloop(10290,"it_",@let("z"=>@getfield("%v","reset"),
@switch(@substr("%z",-1,1),";","",@setfield("%v","reset",@print(
@getfield("%v","reset"),";"
)))
));
@s("big_reset","");
@fieldloop(10290,"it_",@s("big_reset",@print(
@g("big_reset"),@getfield("%v","reset")," "
)));
TEMP
@succ #11329 = @fieldloop(10290,"it_",@print( "%v : ", @getfield("%v","reset"), "%c" ));
---
===
My first Zork reference.
@create mailbox;box;mail box;m
@set #9896 = expert
@ofail #9896 = tries to rip the mailbox off the wall, but fails.
@fail #9896 = @tell("%#","The mailbox is solidly attached to the wall.");
@call(10633,"each_turn");
@lock #9896 = #-1
@zone #9896 = #10719
@desc #9896 = @tell("%#","There's an old-fashioned mailbox that looks
somewhat out of place, mounted on the wall. It would probably look better
in front of a white house. The mailbox is closed.");
@call(10633,"each_turn");
First of all, the mailbox is always closed. Simpler that way. Second, if you're already holding the leaflet, you won't find it again, but otherwise you do.
@action open mailbox;open box;open mail;open mail box;look in mailbox;
l in mailbox;look in box;l in box = mailbox : nowhere
@succe #9904 = @switch(@location(9908),"%#",@print( @tell("%#","You open
the mailbox again, but there's nothing more inside, so you close it
again."),@tellroom(@location("%#"),"%#","%n opens the mailbox again, sees
nothing more inside, and closes it again.")),@print(@move(9908,"%#"),
@tellroom(@location("%#"),"%#","%n opens the mailbox. Inside is a leaflet,
which %s takes."),@tell("%#","You open the mailbox. Inside is a leaflet,
which you take."))); @call(10633,"each_turn");
@set #9904 = dark
@desc #9904 =
The leaflet is meant to be a quick and dirty way to tell people what's new in the CE Realm, just by me changing or appending to the leaflet's description.
@create leaflet;paper;letter;missive
@set #9908 = slippery
@field #9908 = text : "Cosmic Encounter is a board game where players are
aliens who battle each other for planetary bases using strange alien
powers. Originally published by Eon Games, later by Games Workshop, then
Mayfair Games, and now Hasbro. This homage is based loosely on the original
version." -- DavidW.
%c Jun 04/01: "Rumors of the Praw, a mythical place believed to be
somewhere beyond the dread Warp, begin to circulate. Adventurers baffled."
%c Jun 19/01: "New Hangman game seen in the Orange System!"
%c Sep 07/01: "Legend Lips added to the spaceport's Museum!"
%c Nov 08/01: "The Siren enchants crowds with her voice on planet
Djetsetia! (Blue System)"
@field #9908 = reset : @move(9908,11718);
@field #9908 = ohomemsg : is picked up by a cleaning robot and taken away.
@zone #9908 = #10719
@desc #9908 = @tell("%#",@call(9908,"text")); @call(10633,"each_turn");
@open up;u;out;o;enter platform;stand on platform;step on platform;
step onto platform;board platform = #881
@odrop #8885 = enters into view from below, carried by a floating platform
that rises gently up to the ground. %n steps off the platform.
@field #8885 = exitto : back to Open Chamber
@osucc #8885 = steps onto the floating platform. It rises, taking %o back
to the open chamber. Moments later, a new platform lowers into place.
@succe #8885 = @tell("%#","You step onto the floating platform. It rises
back up to the open chamber, leaving the spaceport behind you. \"Thank
you for visiting the Cosmic Encounter Realm,\" says a pleasant female
voice from a hidden speaker. You disembark."); @call(10633,"each_turn");
@desc #8885 = @tell("%#","The platform appears to be little more than
a simple disc of an unknown alien metal. But you know that if you stand
on it, it'll carry you back up to the rest of the ifMUD.");
@call(10633,"each_turn");
@open east;e = #8893
@odrop #8894 = enters from the lobby to the west.
@field #8894 = exitto : to Observation Deck
@osucc #8894 = goes east.
@succe #8894 = You walk east.
@desc #8894 = @tell("%#","A large observation deck can be seen to the east.
Even from here, you can see that the windows provide an excellent view of
the vacuum of space outside the spaceport."); @call(10633,"each_turn");
@open west;w = #10752
@odrop #10753 = enters from the lobby to the east.
@field #10753 = exitto : to Promenade
@osucc #10753 = goes west.
@succe #10753 = You walk west.
@desc #10753 = @tell("%#","A long promenade lies to the west. You can't see
where it goes to from here."); @call(10633,"each_turn");
@open north;n = #8905
@odrop #8911 = enters from the lobby.
@field #8911 = exitto : to North Departures
@osucc #8911 = goes north.
@succe #8911 = You walk north.
@desc #8911 = @tell("%#","To the north, you see the North Departure Lounge.
From there, you can board shuttles to the gas giant, space dust, and rings
systems."); @call(10633,"each_turn");
@open south;s = #8982
@odrop #8994 = enters from the lobby.
@field #8994 = exitto : to South Departures
@osucc #8994 = goes south.
@succe #8994 = You walk south.
@desc #8994 = @tell("%#","To the south, you see the South Departure Lounge.
From there, you can board shuttles to the six-pact, spiral, and pulsar
systems."); @call(10633,"each_turn");
@open down;d;escalator;ride escalator;get on escalator;take escalator = #9087
@odrop #9150 = comes down the escalator.
@field #9150 = exitto : to Shops
@osucc #9150 = takes the escalator down.
@succe #9150 = You take the escalator down...
@desc #9150 = @tell("%#","This escalator takes you down to the gift shop
and food court."); @call(10633,"each_turn");
@dig Observation Deck
@field #8893 = each_turn : @switch(@rand(3),0,@tellroom(8893,"",
@print("%cThrough the tall windows, you see a ",@call(8893,"randshuttle"),
" zooming away from the spaceport.")),1,@tellroom(8893,"",@print("%cThrough
the tall windows, you see a ",@call(8893,"randshuttle"),
" approaching the spaceport.")))
@field #8893 = exit_0 : 8896
@field #8893 = nexits : 1
@field #8893 = randshuttle : @switch(@rand(8),0,"red shuttle",
1,"orange shuttle",2,"yellow shuttle",3,"green shuttle",4,"blue shuttle",
5,"violet shuttle",6,"silver taxicab",7,"ultraviolet tour bus")
@zone #8893 = #10719
@desc #8893 = @tell("%#","This is a large, semi-circular observation deck,
with tall windows to look at, and several
sofas to sit on. Everything is clean and modern, but perhaps
too much so for your tastes."); @call(10633,"each_turn");
@create tall windows;windows;tall window;window;tw
@lock #9540 = #-1
@zone #9540 = #10719
@set #9540 = dark
@field #9540 = search : @call(9540,"description");
@desc #9540 = @tell("%#","Tall floor-to-ceiling windows make up the entire
eastern wall, which curves outward. Through the windows, you have an
impressive view of the surrounding stellar neighbourhood. Countless stars
dot the limitless black void, except for one blacker than black hexagon
- which can only be the dread Warp - noticeable only because of the stars
which seem to frame it where *it* isn't.%cTo distract yourself from this
chilling sight, you lower your eyes downward, and watch the shuttles scurry
to and fro around the spaceport."); @call(10633,"each_turn");
@create black hexagon;black hole;warp;hexagon;bh
@set #9543 = dark
@lock #9543 = #-1
@zone #9543 = #10719
@desc #9543 = @tell("%#","It hurts your eyes to look at the Warp, as if
light itself was being sucked out your eyes to feed its hunger, though
you know that's impossible. Strange that it's a hexagon, though. You
always thought black holes were round. And you don't see the rumoured
Praw nearby either, but that's probably because it's a myth.");
@call(10633,"each_turn");
If you search the sofa, you might find a dusty lucre! Also, pushing one of sofas will reveal a maintenance portal.
@create sofas;sofa;chairs;chair;couches;couch;seats;seat;seating
@lock #9567 = #-1
@set #9567 = dark
@fail #9567 = @tell("%#","The sofas are large, heavy pieces of
furniture, and besides... they seem to be bonded to the floor, except for
the one that's on casters. You can't take them."); @call(10633,"each_turn");
@field #9567 = search : @switch(@location(10710),11718,
@print(@move(10710,"%#"), @tell("%#","You search between the sofa cushions
and find a dusty lucre! You take it."),@tellroom(@location("%#"),"%#","%n
searches between the sofa cushions and finds a dusty lucre, which %s
takes.")),@print(@tell("%#","You search between the sofa cushions but
find nothing."), @tellroom(@location("%#"),"%#","%n searches between the
sofa cushions, but finds nothing."))); @call(10633,"each_turn");
@zone #9567 = #10719
@desc #9567 = @tell("%#","The sofas are upholstered in solid
colors, mostly oranges and browns, and look quite comfortable to sit on,
or even sleep on, if it came to that."); @call(10633,"each_turn");
@field #9567 = ismoved : 0
@field #9567 = pull : @call("%!","push");
@field #9567 = push : @switch(@g("ismoved"),1,@print(
@s("ismoved",0), @setflag(11073,"dark"),
@tell("%#","You push the sofa back into the northeast corner, hiding the
maintenance portal from view."),
@tellroom(@location("%#"),"%#","%n pushes a sofa into the northeast
corner, hiding the maintenance portal from view.")
),@print(
@s("ismoved",1), @setflag(11073,"!dark"),
@tell("%#","You pull one of the sofas away from the northeast corner,
revealing a hidden maintenance portal in the floor!"),
@tellroom(@location("%#"),"%#","%n pulls one of the sofas away from the
northeast corner, revealing a hidden maintenance portal in the floor!")
)); @call(10633,"each_turn");
---
@field #9567 = push : @switch(@g("ismoved"),1,@print( @s("ismoved",0), @setflag(11073,"dark"), @tell("%#","You push the sofa back into the northeast corner, hiding the maintenance portal from view."), @tellroom(@location("%#"),"%#","%n pushes a sofa into the northeast corner, hiding the maintenance portal from view.")),@print( @s("ismoved",1), @setflag(11073,"!dark"), @tell("%#","You pull one of the sofas away from the northeast corner, revealing a hidden maintenance portal in the floor!"), @tellroom(@location("%#"),"%#","%n pulls one of the sofas away from the northeast corner, revealing a hidden maintenance portal in the floor!"))); @call(10633,"each_turn");
===
@open sit on sofa;sit on chair;sit;sit down = nowhere
@set #9585 = dark
@succe #9585 = @tell("%#","You sit down for a few moments to rest your
feet."); @call(10633,"each_turn");
@osucc #9585 = sits down on one of the sofas.
The dusty lucre hangs out in the Cradle, until you search the sofa.
@create dusty lucre;lucre;coin;dusty coin;dl @zone #10710 = #10719 @field #10710 = reset : @move(10710,11718); @desc #10710 = Lucre is the official coin of the CE Realm, used by aliens everywhere. It's a yellow square that's 3cm wide, 3mm thick, and made from an alloy of gold and other metals. The only markings printed on it are stylized letter L's on both sides. @field #10710 = comment : This is the lucre that's found in the Observation Deck's sofa.
Actually, the spaceport is in orbit, a LARGE orbit, around the Warp, and that's why the stars are moving. But if people want to think that I'm spinning the port to create artifical gravity instead, I don't mind. They'll be wrong, but I don't mind. :)
@create stars;void;space;outer space
@set #9584 = dark
@lock #9584 = #-1
@zone #9584 = #10719
@desc #9584 = @tell("%#","As you watch the stars, you notice that they're
moving slightly off to the left across the windows. The spaceport must be
rotating slightly."); @call(10633,"each_turn");
@create shuttles;ships;spaceships
@set #9586 = dark
@lock #9586 = #-1
@zone #9586 = #10719
@desc #9586 = @tell("%#","Those must be the shuttles that take people to
other solar systems in this galaxy. Amazing that intergalactic travel can
be done nowadays with such small vessels. Someday, you've just *got* to
get a good look under the hood of one of those babies.");
@call(10633,"each_turn");
The Zot! comic is here both as a hint that there'll be a door floating out in space somewhere, and acknowledgement of where I 'borrowed' the idea. Hopefully, by placing the comic here near the view of the Warp, the player will associate the two together. Maybe.
@create Zot! comic book;zot!;zot;zot comic book;comic book;comic;book;
zot comic;zot! comic;Zcb
@drop #9889 = @tell("%#","You drop the Zot! comic book.");
@call(10633,"each_turn");
@odrop #9889 = drops a Zot! comic book.
@field #9889 = reset : @move(9889,8893);
@osucc #9889 = picks up the Zot! comic book.
@succe #9889 = @tell("%#","You pick up the Zot! comic book.");
@call(10633,"each_turn");
@zone #9889 = #10719
@desc #9889 = @tell("%#","It's an issue of a comic book character called
Zot by Scott McCloud, issue number 8 to be exact. It shows Zot and a
girl named Jenny going through an ordinary wooden door floating in
outer space. The cover copy reads: \"It had to happen! Through The
Door!!\"."); @call(10633,"each_turn");
@open west;w = #8856
@odrop #8896 = enters from the observation deck to the east.
@field #8896 = exitto : to Lobby
@osucc #8896 = goes west.
@succe #8896 = You walk west.
@desc #8896 = @tell("%#","You see the main lobby to the west."); @call(10633,"each_turn");
First, the portal isn't even visible until you've pushed the sofa away from the wall. Second, you must have a ID card from my locker before the portal will open. Third, the portal goes to the Taxi Stop, but way up near the ceiling, and with gravity turned sideways!
@open down;d;enter maintenance portal;enter portal = nowhere
@set #11073 = dark
@field #11073 = exitto : to ???
@desc #11073 = @switch(1,@testflag("%!","dark"),
@tell("%#","I don't see that here."),
@tell("%#","The circular maintenance portal in the floor is closed.
There is no obvious mechanism to open it, although the words
\"Authorized Personnel Only\" printed on the portal make it clear
that it can be opened.")); @call(10633,"each_turn");
@succ #11073 = @switch(1,@testflag("%!","dark"),@print(
@tell("%#","There's no obvious exit in that direction.")
),@or(@eq("%#",@location(10362)),@eq("%#",@location(11163)),
@eq("%#",@location(11164)),@eq("%#",@location(11165)),
@eq("%#",8796)),@print(
@tellroom(@location("%#"),"%#","%n approaches the portal, and a hidden
sensor sweeps over %o and %p possessions. A hollow voice says
\"Authorization Approved\", the portal irises open, and %s steps down,
disappearing into the hole. As soon as %s is gone from view, the portal
closes behind %o."),
@tell("%#","As you approach the portal, a hidden sensor sweeps over
you and your possessions. A hollow voice says \"Authorization Approved\",
and the portal irises open. You step down into the portal...%cand
suddenly gravity takes a 90 degree turn!"),
@setfield(9448,"%#_orientation",1),
@move("%#",9448)
),@print(
@tellroom(@location("%#"),"%#","%n approaches the portal, and a hidden
sensor sweeps over %o and %p possessions. A hollow voice says
\"Authorization Denied\"."),
@tell("%#","As you approach the portal, a hidden sensor sweeps over
you and your possessions. A hollow voice says \"Authorization Denied\"."),
@call(10633,"each_turn")
));
---
@succ #11073 = @switch(1,@testflag("%!","dark"),@print( @tell("%#","There's no obvious exit in that direction.")),@or(@eq("%#",@location(10362)),@eq("%#",@location(11163)), @eq("%#",@location(11164)),@eq("%#",@location(11165)), @eq("%#",8796)),@print( @tellroom(@location("%#"),"%#","%n approaches the portal, and a hidden sensor sweeps over %o and %p possessions. A hollow voice says \"Authorization Approved\", the portal irises open, and %s steps down, disappearing into the hole. As soon as %s is gone from view, the portal closes behind %o."), @tell("%#","As you approach the portal, a hidden sensor sweeps over you and your possessions. A hollow voice says \"Authorization Approved\", and the portal irises open. You step down into the portal...%cand suddenly gravity takes a 90 degree turn!"), @setfield(9448,"%#_orientation",1), @move("%#",9448)),@print( @tellroom(@location("%#"),"%#","%n approaches the portal, and a hidden sensor sweeps over %o and %p possessions. A hollow voice says \"Authorization Denied\"."), @tell("%#","As you approach the portal, a hidden sensor sweeps over you and your possessions. A hollow voice says \"Authorization Denied\"."), @call(10633,"each_turn")));
===
Still not completely sure where all this is going, but so far: The Red system is a tribute to Beanworld. The Orange system is shaping into a collection of game worlds (that are taking a very long time to write). The Yellow system is Orwellian.
The hidden speaker system code is mostly here. The altered lyrics to "White Rabbit" is a hint on which locker to open in the washrooms. Quiet time between songs is intentional.
@dig North Departure Lounge
@field #8905 = playsong : @switch(@getfield(10421,"setting"),"on",
@let("z"=>@getfield(8905,@print("songline_",@getfield(8905,"the_songline"))),
@print( @switch(@substr("%z",0,1),
"\"",@tellroom(@location("%#"),"","(from speaker) %z"),
"A",@tellroom(@location("%#"),"","%z")),
@setfield(8905,"the_songline",
@mod(@add(1,@getfield(8905,"the_songline")),95)))));
@field #8905 = songline_1 : A hidden speaker begins to play "White Rabbit"
by Jefferson Airplane.
@field #8905 = songline_2 : "One pill makes you larger... And one pill
makes you small..."
@field #8905 = songline_3 : "And the ones that mother gives you... Don't
do anything at all..."
@field #8905 = songline_4 : "Go page Alex... What is ten feet tall?..."
@field #8905 = songline_5 : "And if you go chasing rabbits... And you
know you're going to fall..."
@field #8905 = songline_6 : "Tell 'em a hookah smoking caterpillar...
Has given you the call..."
@field #8905 = songline_7 : "Go page Alex... What is ten feet tall?..."
@field #8905 = songline_8 : "When men on the chessboard... Get up and
tell you where to go..."
@field #8905 = songline_9 : "And you've just had some kind of mushroom...
And your mind is moving low..."
@field #8905 = songline_10 : "Go ask Alex... I think he'll know..."
@field #8905 = songline_11 : "When logic and proportion... Have fallen
sloppy dead..."
@field #8905 = songline_12 : "And the White Knight is talking
backwards... And the Red Queen's 'off with her head!'..."
@field #8905 = songline_13 : "Remember what the dormouse said: Feed your
head... Feed your head... Feed your head!"
@field #8905 = songline_18 : A hidden speaker begins to play "Slime
Creatures from Outer Space" by Weird Al Yankovic.
@field #8905 = songline_19 : "Things just haven't been the same... Since
the flying saucer came... Now the aliens are on the loose..."
@field #8905 = songline_20 : "Well, we tried to hold 'em back... Tried to
ward off their attack... But our atom bombs were just no use..."
@field #8905 = songline_21 : "They were ugly, they were mean... Biggest
heads I ever seen... They made everybody scream and shout..."
@field #8905 = songline_22 : "First they leveled Tokyo... Then New York
was next to go... Boy I really wish they'd cut it out..."
@field #8905 = songline_23 : "They wasted everybody on my block... There
goes the neighborhood..."
@field #8905 = songline_24 : "They'll zap you with their death ray
eyes... And blow you up real good..."
@field #8905 = songline_25 : "Run for your lives! (...slime creatures
from outer space, slime creatures from outer space...)"
@field #8905 = songline_26 : "They're not very nice to the human race
(...slime creatures from outer space...)"
@field #8905 = songline_27 : "There's more comin' every day... And they
just won't go away... Now they're reproducing in the sewers..."
@field #8905 = songline_28 : "They got slimy lizard skin... And an evil
lookin' grin... And they sure could use some manicures..."
@field #8905 = songline_29 : "They got hands all covered with fungus...
They got eyes like some kinda bug..."
@field #8905 = songline_30 : "I sure hope they don't come in here...
I just shampooed the rug..."
@field #8905 = songline_31 : "Run for your lives! (...slime creatures from
outer space, Slime creatures from outer space...)"
@field #8905 = songline_32 : "They're really makin' a mess of this
place... (slime creatures. slime creatures.)"
@field #8905 = songline_38 : A hidden speaker begins to play selections
from Holst's "The Planets".
@field #8905 = songline_43 : A hidden speaker begins to play "Space
Oddity" by David Bowie.
@field #8905 = songline_44 : "Ground Control to Major Tom. Ground Control
to Major Tom."
@field #8905 = songline_45 : "Take your protein pills and put your helmet
on."
@field #8905 = songline_46 : "Ground Control to Major Tom. Commencing
countdown, engines on."
@field #8905 = songline_47 : "Check ignition and may God's love be with
you..."
@field #8905 = songline_48 : "Ten. Nine. Eight. Seven. Six. Five. Four.
Three. Two. One. Liftoff..."
@field #8905 = songline_49 : "This is Ground Control to Major Tom. You've
really made the grade."
@field #8905 = songline_50 : "And the papers want to know whose shirts
you wear. Now it's time to leave the capsule if you dare."
@field #8905 = songline_51 : "This is Major Tom to Ground Control. I'm
stepping through the door."
@field #8905 = songline_52 : "And I'm floating in a most peculiar way. And
the stars look very different today."
@field #8905 = songline_53 : "For here... am I sitting in a tin can. Far
above the world."
@field #8905 = songline_54 : "Planet Earth is blue, and there's nothing I
can do.
@field #8905 = songline_55 : "Though I'm past one hundred thousand miles,
I'm feeling very still."
@field #8905 = songline_56 : "And I think my spaceship knows which way to
go. Tell my wife I love her very much she knows..."
@field #8905 = songline_57 : "Ground Control to Major Tom. Your circuit's
dead, there's something wrong."
@field #8905 = songline_58 : "Can you hear me, Major Tom? Can you hear me,
Major Tom?
@field #8905 = songline_59 : "Can you hear me, Major Tom? Can you --"
@field #8905 = songline_60 : "Here am I floating round my tin can. Far
above the Moon."
@field #8905 = songline_61 : "Planet Earth is blue, and there's nothing I
can do."
@field #8905 = songline_66 : A hidden speaker begins to play "Killer
Robots From Venus" by Arrogant Worms.
@field #8905 = songline_67 : "About six months ago someone came by with a
petition, said: We wanna stop the folks moving in next door."
@field #8905 = songline_68 : "I refused to sign and told them: Everyone
was welcome, cuz that's what neighbourhoods are for."
@field #8905 = songline_69 : "So they moved in and I'll admit they looked
peculiar. They invited me to a friendly barbeque."
@field #8905 = songline_70 : "I'm glad I got to know 'em, and let me tell
you something: they may be metallic, but they're just like me and you."
@field #8905 = songline_71 : "No, there's nothing wrong with Killer Robots
from Venus."
@field #8905 = songline_72 : "They gave me zucchini from their garden
yesterday." <<"They are Very Fresh">>
@field #8905 = songline_73 : "No, there's nothing wrong with Killer Robots
from Venus."
@field #8905 = songline_74 : "You may disagree but I think they're A-OK."
@field #8905 = songline_75 : "My buddy Charlie never got off the Robot's
backs. Then one day, him and his whole house disappeared."
@field #8905 = songline_76 : "I talked about it to my neighbours,
the Killer Robots from Venus. They couldn't help me, but agreed that it
was weird."
@field #8905 = songline_77 : "No, there's nothing wrong with Killer Robots
from Venus."
@field #8905 = songline_78 : "They always mow their lawn, and they joined
the PTA. <<"Because we care">>
@field #8905 = songline_79 : "No, there's nothing wrong with Killer Robots
from Venus."
@field #8905 = songline_80 : "You may disagree, but I think they're A-OK."
@field #8905 = songline_81 : "They had us over for a New Year's party.
Though it was ten below, there was food and drink a-plenty."
@field #8905 = songline_82 : "They got excited as we counted down with
them."
@field #8905 = songline_83 : "And when we kissed them, our lips stuck to
their heads..." <<"Ouch!">>
@field #8905 = songline_84 : "I was watchin' the news last night, and I
saw something funny."
@field #8905 = songline_85 : "Killer Robots from somewhere decimated
Montreal."
@field #8905 = songline_86 : "I wondered, could it be my neighbours, the
Killer Robots from Venus?"
@field #8905 = songline_87 : "Could it be them after all...???" "Oh no,
they're so nice." "Yeah."
@field #8905 = songline_88 : "No, there's nothing wrong with Killer Robots
from Venus."
@field #8905 = songline_89 : "They applauded for my kid at the Christmas
play... <<"He was the best shepherd">>
@field #8905 = songline_90 : "No, there's nothing wrong with Killer Robots
from Venus."
@field #8905 = songline_91 : "You may disagree but I think they're A-OK."
<<"They're OK!">>
@field #8905 = the_songline : 42
@field #8905 = nsonglines : 95
@field #8905 = each_turn : @call(8905,"playsong")
@field #8905 = listen : @switch(@getfield(10421,"setting"),"on",
@let("z"=>@getfield(8905,"the_songline"), @switch(1,
@and(@lt("1","%z"),@lt("%z","14")), "A hidden speaker is playing \"White
Rabbit\" by Jefferson Airplane. The lyrics aren't quite how you
remember them.",
@and(@lt("18","%z"),@lt("%z","33")), "A hidden speaker is playing \"Slime
Creatures from Outer Space\" by Weird Al Yankovic.",
@and(@lt("38","%z"),@lt("%z","43")), "A hidden speaker is playing
selections from Holst \"The Planets\".",
@and(@lt("43","%z"),@lt("%z","62")), "A hidden speaker is playing \"Space
Oddity\" by David Bowie.",
@and(@lt("66","%z"),@lt("%z","92")), "A hidden speaker is playing \"Killer
Robots From Venus\" by The Arrogant Worms.",
"You hear nothing unusual.")), "You hear nothing unusual.");
@field #8905 = exit_0 : 10652
@field #8905 = exit_1 : 9284
@field #8905 = exit_2 : 9386
@field #8905 = exit_3 : 10652
@field #8905 = exit_4 : 9243
@field #8905 = exit_5 : 8931
@field #8905 = nexits : 6
@zone #8905 = #10719
@desc #8905 = @tell("%#","Also known as the \"hot lounge\" for its mural of
flames and fire. The black ceiling depicts the
galactic north hemisphere of the CE Realm, with long lines marked in red,
orange, and yellow to show the shuttle routes. Seating is plentiful.
Departure gates line the north wall, and arrivals are downstairs via the
escalator."); @call(10633,"each_turn");
@open south;s = #8856
@odrop #8931 = enters from the north.
@field #8931 = exitto : to Lobby
@osucc #8931 = goes south.
@succe #8931 = You walk south.
@desc #8931 = @tell("%#","You see the lobby in that direction.");
@call(10633,"each_turn");
@open down;d;escalator;ride escalator;get on escalator;
take escalator = #9000
@odrop #9042 = comes down the escalator.
@field #9042 = exitto : to Arrivals
@osucc #9042 = rides down the escalator.
@succe #9042 = You ride down the escalator...
@desc #9042 = @tell("%#","This escalator will take you down to the North
Arrival Lounge."); @call(10633,"each_turn");
@open northwest;nw;enter red gate;enter red;enter rg;red gate;rg = #9231
@odrop #9243 = arrives from the spaceport.
@field #9243 = exitto : via red gate to Gas Giant
@osucc #9243 = enters the red gate to the northwest.
@succe #9243 = Beyond the red gate, a long service corridor heads
further northwest to the catwalk level of a mid-sized hangar.
Your shuttle is a true flying saucer, a round disk painted bright cherry
red. Several aliens and maintenance robots are performing last minute
safety tests before the launch.%c Inside the shuttle,
you quickly find a seat and strap yourself in. The hatch closes,
the shuttle hovers, then zooms into space!! The spaceport receeds from
view, and then... >BLINK<%c ...it is replaced by a gas
giant eight times as large as Jupiter. This too, passes from view,
as the shuttle zips into an orbiting stardisc, and you disembark.
@desc #9243 = @tell("%#","The red gate to the northwest has an animated
hologram of the Gas Giant system floating above its archway.");
@call(10633,"each_turn");
@open north;n;enter orange gate;enter orange;enter og;orange gate;og = #9244
@odrop #9284 = arrives from the spaceport.
@field #9284 = exitto : via orange gate to Space Dust
@osucc #9284 = enters the orange gate to the north.
@succe #9284 = Past the orange gate, a short hallway leads to
a small hangar. The round orange shuttle here has been modified
from its original design; it looks old, but also valued.%c The inside
surprises you, with a row of plants along one wall, and bunk beds instead
of normal seating. So, you lie down on the beds ("When in Rome..."), and
soon the shuttle takes off!... >BLINK<...%c What just happened? You
look around for a window, but there isn't one. You then hear the shuttle
landing, and soon you're standing up again, and entering a new port...
@desc #9284 = @tell("%#","The orange gate to the north has an animated
hologram of the Space Dust system floating above its archway.");
@call(10633,"each_turn");
@open northeast;ne;enter yellow gate;enter yellow;enter yg;yellow gate;yg = #9385
@odrop #9386 = arrives from the spaceport.
@field #9386 = exitto : via yellow gate to Rings
@osucc #9386 = enters the yellow gate to the northeast.
@succe #9386 = Beyond the yellow gate, through archways that scan and
disinfect you, a long service corridor heads further northeast to your
hangar's shuttle. A shuttle you can't see, because the gangway that
leads to it is completely enclosed.%c Inside, the shuttle is cramped
and uncomfortable. (A separate security camera for each passenger??) Once
you're seated, the hatch closes, the shuttle hovers, then it zooms into
space!! Nobody talks. Nothing to look at, except maybe the cameras.
Then... >BLINK<...%c You're in a new solar system. Quickly and
efficiently, you are hustled out of the shuttle.
@desc #9386 = @tell("%#","The yellow gate to the northeast has an animated
hologram of the Rings system floating above its archway.");
@call(10633,"each_turn");
@open west;w = nowhere
@field #10652 = exitto : to Men's Room
@field #10652 = action2 : 9219
@field #10652 = osuccess2 : enters the Men's Room.
@field #10652 = odrop2 : enters from the upper east door.
@field #10652 = lock2 : @and(@testflag(@getfield(10633,"the_alien"),"male"),
@not(@testflag(@getfield(10633,"the_alien"),"female")))
@succe #10652 = @switch("%s","he",@print(@tell("%#","You enter the Men's
Room."), @tellroom(@location("%#"),"%#","%n enters the Men's Room."),
@tellroom(9219,"","%n enters from the upper east door."),
@move("%#",9219)), @print(@tell("%#","A male washroom sprite appears and
bars your way. \"This is the Men's Room! You can't come in here! It's for
males only!\" he tells you, and then vanishes."),
@tellroom(@location("%#"),"%#","%n tries to enter the Men's Room, but a
washroom sprite bars %p way."),@call(10633,"each_turn")))
@desc #10652 = @tell("%#","That's the door to the Men's washroom.");
@call(10633,"each_turn");
@open east;e = nowhere
@field #10653 = exitto : to Unmen's Room
@field #10653 = action2 : 9223
@field #10653 = osuccess2 : enters the Unmen's Room.
@field #10653 = odrop2 : enters from the upper west door.
@field #10653 = lock2 : @and(@not(@testflag(@getfield(10633,"the_alien"),
"male")), @not(@testflag(@getfield(10633,"the_alien"),"female")))
@succe #10653 = @switch("%s","it",@print(@tell("%#","You enter the Unmen's
Room."),@tellroom(@location("%#"),"%#","%n enters the Unmen's Room."),
@tellroom(9223,"","%n enters from the upper east door."),
@move("%#",9223)), @print(@tell("%#","A neuter washroom sprite appears
and bars your way. \"This is the Unmen's Room! You can't come in here!
It's for neuters only!\" it tells you, and then vanishes."),
@tellroom(@location("%#"),"%#","%n tries to enter the Unmen's Room, but a
washroom sprite bars %p way."), @call(10633,"each_turn")))
@desc #10653 = @tell("%#","That's the door to the Unmen's washroom.");
@call(10633,"each_turn");
@create hot mural;mural;flames;fire;walls;lava;volcanoes;rivers;hm
@set #11696 = dark
@fail #11696 = @tell("%#","The mural is part of the wall.");
@call(10633,"each_turn");
@lock #11696 = #-1
@desc #11696 = @tell("%#","Impressive. Painted on the walls is a panoramic
vista of a burning landscape, punctuated by distant volcanoes pouring
forth rivers of molten lava. Flames and fire are everywhere. A wall-sized
picture postcard from Hell."); @call(10633,"each_turn");
@field #11696 = push : @tell("%#","You feel nothing unusual. The mural
only *looks* hot."); @call(10633,"each_turn");
The south lounge is the mirror image of the north lounge. I have yet to have a clear idea where I'm going with these solar systems, but here's what I've got so far: Green is all about money and advertising. Blue is high-tech and science. Violet is just weirdo bizarro.
@dig South Departure Lounge
@field #8982 = each_turn : @call(8905,"playsong")
@field #8982 = exit_0 : 9469
@field #8982 = exit_1 : 9486
@field #8982 = exit_2 : 9492
@field #8982 = exit_3 : 10654
@field #8982 = exit_4 : 10655
@field #8982 = exit_5 : 8998
@field #8982 = nexits : 6
@zone #8982 = #10719
@field #8982 = listen : @call(8905,"listen")
@desc #8982 = @tell("%#","Also known as the \"cold lounge\" for its mural
of water and marine life. The black ceiling
depicts the galactic south hemisphere of the CE Realm, with long lines
marked in green, blue, and violet to show the shuttle routes. Seating is
plentiful. Departure gates line the south wall, and arrivals are downstairs
via the escalator."); @call(10633,"each_turn");
@open north;n = #8856
@odrop #8998 = enters from the south lounge.
@field #8998 = exitto : to Lobby
@osucc #8998 = goes north.
@succe #8998 = You walk north.
@desc #8998 = @tell("%#","The lobby is in that direction.");
@call(10633,"each_turn");
@open down;d;escalator;ride escalator;get on escalator;take escalator = #9075
@odrop #9080 = comes down the escalator.
@field #9080 = exitto : to Arrivals
@osucc #9080 = rides down the escalator.
@succe #9080 = You ride down the escalator...
@desc #9080 = @tell("%#","This escalator will take you down to the
South Arrival Lounge."); @call(10633,"each_turn");
@open southeast;se;enter green gate;enter green;enter gg;green gate;gg = #9453
@odrop #9469 = arrives from the spaceport.
@field #9469 = exitto : via green gate to Six-Pact
@osucc #9469 = enters the green gate to the southeast.
@succe #9469 = Beyond the green gate, a long service corridor
heads further southeast past numerous advertisements:%c "Doesn't your
pet deserve NUTRI-CHOW(R)?"%c "Smell your best with
EVERBLEST(tm)!!"%c "ORANGE JUICY-FIZZ(R) Brand Pop: you just
gotta have it!"%c Eeargh. Your shuttle, when you find
it, is a round coin of a spaceship - green. Inside, you sit
in an easy chair equipped with an HV screen that you can't turn off. You
also get a complimentary packet of Snix-Snax(tm), whose primary
ingredients appear to be potatoes and sugar. Then there's an "unavoidable
delay", so you watch the holo and eat the snacks. When the holo ads start
their third loop, finally, the shuttle hovers, then zooms
into space! And then... >BLINK<...%c A new solar system: a green
stardisc, and a sun with six planets. Ducking out
between the "thank you" and the "have a nice day", you escape to...
@desc #9469 = @tell("%#","An animated hologram of the Six-Pact System
hovers above the green gate to the southeast."); @call(10633,"each_turn");
@open south;s;enter blue gate;enter blue;enter bg;blue gate;bg = #9474
@odrop #9486 = arrives from the spaceport.
@field #9486 = exitto : via blue gate to Spiral
@osucc #9486 = enters the blue gate to the south.
@succe #9486 = Past the blue gate, a short hallway leads to a
small hangar. The round blue shuttle is elegant in its simplicity.
Scientists are having a lively argument nearby.%c The inside of the
shuttle is not as well maintained; there's graffiti and peculiar smells.
Soon the shuttle takes off into space! It turns away from the spaceport,
glides into a new direction, then.... >BLINK<...%c Suddenly
a new solar system comes into view: five planets and a pale ice-blue sun,
but not all in the same plane. Odd. Before you know it, the shuttle lands,
and you're entering a new port...
@desc #9486 = @tell("%#","An animated hologram of the Spiral System hovers
above the blue gate to the south."); @call(10633,"each_turn");
@open southwest;sw;enter violet gate;enter violet;enter vg;violet gate;vg = #9475
@odrop #9492 = arrives from the spaceport.
@field #9492 = exitto : via violet gate to Pulsar
@osucc #9492 = enters the violet gate to the southwest.
@succe #9492 = Beyond the violet gate, a long corridor
heads southwest to a mid-sized hangar which contains a round violet
shuttle. Surprisingly, the shuttle is split into two free floating
halves. Pairs of tracker beams pick you up and place you into the
shuttle's lower half. Like a mother hen putting her chicks into her nest.
Not pleasant.%c Then the two halves of the shuttle slam together!
It's completely dark. You can't hear a thing. That's when you smell the
gas...%c (You dream of a pair of hexagons: one black, one
ultrablack.)%c (You dream of a pair of walls: one of brick, one of
graffiti.)%c You wake up, no longer in the shuttle...
@desc #9492 = @tell("%#","An animated hologram of the Pulsar System hovers
above the violet gate to the southwest."); @call(10633,"each_turn");
@open west;w = nowhere
@field #10654 = exitto : to Women's Room
@field #10654 = action2 : 9432
@field #10654 = osuccess2 : enters the Women's Room.
@field #10654 = odrop2 : enters from the upper east door.
@field #10654 = lock2 : @and(@not(@testflag(@getfield(10633,"the_alien"),
"male")),@testflag(@getfield(10633,"the_alien"),"female"))
@succe #10654 = @switch("%s","she",@print(@tell("%#","You enter the
Women's Room."),@tellroom(@location("%#"),"%#","%n enters the Women's
Room."),@tellroom(9432,"","%n enters from the upper east door."),
@move("%#",9432)), @print(@tell("%#","A female washroom sprite appears
and bars your way. \"This is the Women's Room! You can't come in here!
It's for females only!\" she tells you, and then vanishes."),
@tellroom(@location("%#"),"%#","%n tries to enter the Women's Room, but
a washroom sprite bars %p way."), @call(10633,"each_turn")))
@desc #10654 = @tell("%#","That's the door to the Women's washroom.");
@call(10633,"each_turn");
@open east;e = nowhere
@field #10655 = exitto : to Hamen's Room
@field #10655 = action2 : 9437
@field #10655 = osuccess2 : enters the Hamen's Room.
@field #10655 = odrop2 : enters from the upper west door.
@field #10655 = lock2 :
@and(@testflag(@getfield(10633,"the_alien"),"male"),
@testflag(@getfield(10633,"the_alien"),"female"))
@succe #10655 = @switch("%s",{"he","she","it"},@print(
@tell("%#","A hermaphrodite washroom sprite appears and bars your way.
\"This is the Hamen's Room! You can't come in here! It's for
hermaphrodites and transgenders only!\" he/she tells you, and then
vanishes."),@tellroom(@location("%#"),"%#","%n tries to enter the
Hamen's Room, but a washroom sprite bars %p way."),
@call(10633,"each_turn")), @print(@tell("%#","You enter the Hamen's
Room."),@tellroom(@location("%#"),"%#","%n enters the Hamen's Room."),
@tellroom(9437,"","%n enters from the upper west door."),@move("%#",9437)))
@desc #10655 = @tell("%#","That's the door to the Hamen's washroom.");
@call(10633,"each_turn");
@create cold mural;mural;walls;water;marine life;fish;seaweed;
green grasses;purple sand;sand;seabed;ocean floor;cm
@set #11697 = dark
@fail #11697 = @tell("%#","The mural is part of the wall.");
@call(10633,"each_turn");
@lock #11697 = #-1
@desc #11697 = @tell("%#","Painted on the walls is a panoramic vista of
an underwater landscape. In a sea of brillant blue, unusual and colorful
fish swim contentedly amongst the green grasses and purple sands that
line the ocean floor. Very soothing."); @call(10633,"each_turn");
@field #11697 = push : @tell("%#","You feel nothing unusual. The mural
only *looks* cold."); @call(10633,"each_turn");
@dig Promenade
@field #10752 = exit_0 : 10755
@field #10752 = nexits : 1
@zone #10752 = #10719
@desc #10752 = @tell("%#","You're in a long tubular corridor that runs
west to east. The perfectly round walls and ceiling are made from
thousands of cream-colored hexagonal tiles held in place with black
support struts. By contrast, the floor is flat, dark green, and doesn't
seem to be tiled at all."); @call(10633,"each_turn");
@open west;w;door;doors;sliding door;sliding doors;gantry;
attack cone gantry = #10468
@field #10754 = exitto : to Attack Cone Gantry
@fail #10754 = @tell("%#","You start to go west, but the Macron easily
blocks your way.%cMac the Macron says (to you), \"Sorry, human.
Authorized personnel only. You got any valid ID? No? I didn't think
so.\""); @tellroom(@location("%#"),"%#","%n tries to go west, but the
Macron blocks %p path easily."); @call(10633,"each_turn");
@lock #10754 = #8796|#10362|#11163|#11164|#11165
@succe #10754 = You walk west through the sliding doors...
@desc #10754 = @tell("%#","The west end of the promenade ends in a pair
of sliding doors and are labelled \"Attack Cone Gantry - Authorized
Personnel Only!\"."); @call(10633,"each_turn");
@open east;e = #8856
@odrop #10755 = enters from the Promenade to the west.
@field #10755 = exitto : to Lobby
@osucc #10755 = goes east.
@succe #10755 = You walk east.
@desc #10755 = @tell("%#","The east end of the promenade opens out to the
spaceport's lobby."); @call(10633,"each_turn");