@dig Red Stardisc, in orbit above the Gas Giant
@field #9231 = exit_0 : 9417
@field #9231 = exit_1 : 11307
@field #9231 = exit_2 : 11312
@field #9231 = nexits : 3
@zone #9231 = #10719
@desc #9231 = @tell("%#","The stardisc, itself, isn't much to look at, but
the planet below you is magnificant. There's a familiar looking floating
platform on the floor nearby, and three gates to neighbouring systems
by shuttle."); @call(10633,"each_turn");
Beanworld is, of course, the major inspiration for most of what's
in the red system, stealing borrowing half of the concepts
excepting the beans themselves. Again, putting the comic book here
provides the hint and the acknowledgement.
@create Tales of the Beanworld comic book;comic book;book;comic;totb;
beanworld book;bean book;TotBcb
@field #10199 = reset : @move(10199,9231);
@desc #10199 = @tell("%#","This is the classic issue #4 of Larry Marder's
Tales of the Beanworld. Classic, because this is the issue when Beanish
discovers the float factor by adding twinks to mystery pods.");
@call(10633,"each_turn");
@zone #10199 = #10719
@open southeast;se;white gate = #9000
@odrop #9417 = arrives from the Gas Giant System.
@field #9417 = exitto : white gate to Spaceport Eon
@osucc #9417 = exits southeast through the white gate.
@succe #9417 = You catch the next shuttle back to the spaceport...
@desc #9417 = @tell("%#","The white gate to the southeast has an animated
hologram of Spaceport Eon floating above its archway.");
@call(10633,"each_turn");
@open down;d;platform;step on platform;stand on platform;enter platform;
board platform;step onto platform = #10291
@field #10269 = exitto : to planet
@succe #10269 = You step onto the floating platform, and moments later,
a force field bubble is formed around you. Seconds after that, a silver
mist is sprayed into your bubble, which is almost immediately absorbed into
your skin.%c "Please do not be alarmed," says a pre-recorded female
voice. "The nanites we have just inserted into your body are a necessary
measure to protect you from planet Gran'boola'woola's poisonous gases, by
converting them into oxygen and nitrogen. The nanites will vacate your
body on your return to the stardisc. Have a pleasant trip."%c Then the
floor drops open beneath you, or at least it feels like it, as the
platform flies straight down through airless space towards the planet.
Through the thin gases of the uppermost atmosphere, you spot a black
patch that seems more solid than the rest of the planet. As you get
closer, you see that it's some sort of island. The platform lands there,
the force field bubble opens, and you disembark.%c----
@osucc #10269 = steps onto the floating platform, and moments later,
a force field bubble forms around %o. The bubble falls through the
floor, and another floating platform rises up to take its place.
@desc #10269 = @tell("%#","This is a floating platform, very similar to
one that first carried you into the central spaceport. Presumably, you
can just step onto the platform to go down to the planet's surface...
although since this planet is a gas giant, and therefore mostly gas,
\"surface\" might not be quite the right word for it.");
@call(10633,"each_turn");
The Beanworld is a two-dimensional world, sort of, drawn in black and white. Also, the planets in the actual Cosmic Encounter game were also flat b&w illustrations on the game board pieces. The Gas Giant system was introduced in Eon's 9th expansion set.
The planet is named "Gran'boola'woola" in the Beanworld tradition; the lone tree on Beanworld is called Gran'ma'pa. And, this is a big gas giant, after all. It needs a big name.
@create planet;gas giant;gas;giant;Gran'boola'woola
@set #10301 = dark
@lock #10301 = #-1
@zone #10301 = #10719
@desc #10301 = @tell("%#","The planet Gran'boola'woola is a huge gas giant
of a planet, but looks oddly two-dimensional, somehow. Perhaps it's
because it's all black and white, not a hint of color anywhere. You
wonder what it would be like to live on, or rather in, such a place.");
@call(10633,"each_turn");
@open northeast;ne;orange gate = #9244
@odrop #11307 = arrives from the Gas Giant System.
@field #11307 = exitto : orange gate to Space Dust
@osucc #11307 = exits northeast through the orange gate.
@succe #11307 = You catch a shuttle to...
@desc #11307 = @tell("%#","The orange gate to the northeast has an animated
hologram of the Space Dust system floating above its archway.");
@call(10633,"each_turn");
@open south;s;violet gate = #9475
@odrop #11312 = arrives from the Gas Giant System.
@field #11312 = exitto : violet gate to Pulsar
@osucc #11312 = exits south through the violet gate.
@succe #11312 = You catch a shuttle to...
@desc #11312 = @tell("%#","The violet gate to the south has an animated
hologram of the Pulsar system floating above its archway.");
@call(10633,"each_turn");
@dig Floating Island on Gran'boola'woola
@field #10291 = each_turn : @switch(@getfield(10291,"ispray_%#"),
1,@print(@tell("%#","%cHuh? What just happened? How'd you get back here?
Are you still carrying everything you had?"),
@tellroom(10291,"%#","%cHuh? You didn't notice how %n arrived, but %s's
here now."), @setfield(10291,"ispray_%#","")));
@zone #10291 = #10719
@desc #10291 = @tell("%#","Strange little place here. An island of
stablility, yes, but adrift also. A lone tree appears to be thriving here.
A sea of gases surround the island. The gravity is so light here, that you
could probably swim amongst the gases, if you wished.");
@call(10633,"each_turn");
@open swim;down;d;west;w = #10265
@osucc #10299 = dives into the gaseous ocean.
@succe #10299 = You dive into the gaseous ocean...
@desc #10299 = @tell("%#","The gaseous ocean seems to be composed of many
layers. You'll have to swim to find out more."); @call(10633,"each_turn");
At last, the real reason for the nanites: to get rid of all Beanworld artifacts made from the four realities. I've gotta reduce the combinatoric explosion somehow. All you should be able to take away from the gas planet are its two "treasures": the golden apple, and the program card.
@open up;u;step on platform;stand on platform;enter platform;board platform;
step onto platform = #9231
@succe #10300 = @print("You step onto the floating platform, and a force
field bubble snaps into place around you. Moments later, you're
flying back into the red stardisc. After a pause, you suddenly
feel nauseous, and your skin erupts, oozing a thin slime! It doesn't
hurt though. Fascinated, you watch as the slime dissolves",
@switch(@location(10285),"%#", @print(" ...slats",@move(10285,10265))),
@switch(@location(10286),"%#", @print(" ...hoops",@move(10286,10266))),
@switch(@location(10287),"%#", @print(" ...twinks",@move(10287,10267))),
@switch(@location(10288),"%#", @print(" ...chips",@move(10288,10268))),
@switch(@location(10303),"%#", @print(" ...spear",@move(10303,11718))),
@switch(@location(10305),"%#", @print(" ...scooper",@move(10305,11718))),
@switch(@location(10304),"%#", @print(" ...wand",@move(10304,11718))),
". Then the slime falls cleanly and noiselessly into a hidden grating
in the platform. \"Your bio-nanites have vacated your
system,\" says the recorded voice. \"Have a nice day.\" And with that, the
bubble pops, and you step off the platform.%c---");
@osucc #10300 = steps onto the floating platform, and an opaque force field
bubble snaps into place. Moments later, it flies up and out of view.
Moments after that, a second empty platform flies down to take its place.
@desc #10300 = @tell("%#","It's a floating circular platform made of an
unknown alien. If you step on it, it will take you up the the Red Stardisc
that's in orbit."); @call(10633,"each_turn");
@odrop #10300 = steps off a floating platform that just flew into the
stardisc.
This tree is Gran'ma'pa from Beanworld, sort of. It wouldn't be Beanworld without Gran'ma'pa. Except it has a golden apple instead of a sproutbutt.
@create tree;Gran'ma'pa
@set #10476 = dark
@ofail #10476 = tries to pick up the tree. As if.
@fail #10476 = @tell("%#","You *cannot* pick up a tree. Not even in this
light gravity."); @call(10633,"each_turn");
@lock #10476 = #-1
@zone #10476 = #10719
@desc #10476 = @tell("%#",@print("The tree looks almost a child's drawing
of a tree: where you'd expect to see individual branches and leaves is a
spongy solid green mass perched on the tree's Y-shaped trunk. Very 2D.",
@switch(@getfield("10475","ontree"), "1", " An apple, or at least a fruit
that looks like an apple, is nestled within the underside of the tree's
greenery."))); @call(10633,"each_turn");
Why is there a golden apple? To give a reason for the tree being
here, for those explorers who don't know about Gran'ma'pa's place in
Beanworld. It also is your only opportunity to do something useful with the
spear.
How do you get the apple? Throw something throwable at it, either the
spear or the flying pizza, in order to get it.
Why does the apple talk? At the moment, just because it's counterpart,
the sproutbutt, also talks.
What is the apple really? What's the apple good for?
At the moment, your guess is as good as mine.
The apple will be useable in future puzzles, that's all I know right now.
@create golden apple;apple;fruit;ga
@set #10475 = dark
@ofail #10475 = reaches for the golden apple when it screams, "Ah, not with
your *hands*!" It jumps out of the tree, bounces once off the ground, and
back into the tree again.
@fail #10475 = @tell("%#","You begin to reach for the golden apple when it
suddenly screams, \"Ah, not with your *hands*!\" It jumps out of the tree,
bounces once off the ground, and back into the tree again.");
@call(10633,"each_turn");
@field #10475 = reset : @move(10475,10291); @setflag(10475,"dark");
@setfield(10475,"lock","-1"); @setfield(10475,"ontree","1");
@osucc #10475 = picks up the apple.
@field #10475 = ontree : 1
@lock #10475 = #-1
@succe #10475 = @tell("%#","You pick up the apple. \"What, no complaints
about using my hands?\", you ask it. \"Nah, that's just when I'm in the
tree,\" the apple replies."); @call(10633,"each_turn");
@zone #10475 = #10719
@desc #10475 = @tell("%#","It appears to be an apple, except it has six
lobes instead of five. And it's gold. A golden apple.");
@call(10633,"each_turn");
The first of the "four realities". Slats, hoops, twinks, and chips
are a direct steal from homage to Beanworld.
@dig Slatosphere
@zone #10265 = #10719
@desc #10265 = @tell("%#","You are floating amongst an atmospheric band
full of slats, which are long rectangular sticks. On a planet that is
mostly gases, solid objects like these slats can be quite useful.");
@call(10633,"each_turn");
@field #10265 = each_turn :
@switch(@getfield(10265,"pulse"), 0,@setfield(10265,"pulse",1),
1,@setfield(10265,"pulse",2),@print(
@setfield(10265,"pulse",0),
@tellroom(10265,"",@switch(@rand(3),
0,"%cThe eddies of your movements jostle some of the nearby slats.",
1,"%cThe flats of two nearby slats slap!",
2,"%cYou accidently bump a slat with your elbow."
))));
@create slats;bars;sticks;slat;bar;stick
@set #10285 = expert
@field #10285 = reset : @move(10285,10265);
@zone #10285 = #10719
@desc #10285 = @tell("%#","Slats appear to be elemental in nature. They
come in many different sizes, but they all appear to be long, narrow,
rectangular bars."); @call(10633,"each_turn");
@succ #10285 = @tell("%#","You gather and take a stack of slats.");
@call(10633,"each_turn");
@osucc #10285 = gathers and takes a stack of slats.
@drop #10285 = @tell("%#","You drop your stack of slats.");
@call(10633,"each_turn");
@odrop #10285 = drops a stack of slats.
Again, this business of putting these things together to make these tools is straight from Beanworld, but hopefully I've given enough clues that players can noodle this toolmaking opportunity for themselves.
@action put * on slat;place * on slat;attach * to slat;put * on slats;
place * on slats;attach * to slats = slats : nowhere
@set #10441 = puzzle
@succe #10441 = @switch( @object("%#","%0"),
"-1", "But you're not carrying a %0, are you?",
"10285", @call(10441,"with_slat"),
"10286", @call(10441,"with_hoop"),
"10287", @call(10441,"with_twink"),
"10288", @call(10441,"with_chip"),
@call(10441,"with_other"));
@field #10441 = with_slat : @tell("%#","You attach two slats together and
create... a bigger slat! That was useful. Not.");
@tellroom(@location("%#"),"%#","%n attaches two slats together and
creates... a bigger slat! That was useful. Not."); @call(10633,"each_turn");
@field #10441 = with_hoop : @move(10305,"%#");
@tell("%#","You attach a hoop to the end of a slat and create a scooper!");
@tellroom(@location("%#"),"%#","%n attaches a hoop to the end of a slat
and creates a scooper!"); @call(10633,"each_turn");
@field #10441 = with_twink : @move(10304,"%#");
@tell("%#","You attach a twink to the end of a slat and create a magic
wand!", @tellroom(@location("%#"),"%#","%n attaches a twink to the end of
a slat and creates a magic wand!"); @call(10633,"each_turn");
@field #10441 = with_chip : @move(10303,"%#"); @tell("%#","You attach a
chip to the end of a slat and create a spear!"); @tellroom(@location("%#"),
"%#","%n attaches a chip to the end of a slat and creates a spear!");
@call(10633,"each_turn");
@field #10441 = with_other : @tell("%#","You try to attach the %0 to a slat,
but it doesn't seem to make anything useful.");
@tellroom(@location("%#"),"%#","%n tries to attach the %0 to a slat, but
it doesn't seem to make anything useful."); @call(10633,"each_turn");
---
ADD
@succe #10441 = @switch( @object("%#","%0"), "-1", "But you're not carrying a %0, are you?", "10285", @call(10441,"with_slat"), "10286", @call(10441,"with_hoop"), "10287", @call(10441,"with_twink"), "10288", @call(10441,"with_chip"), @call(10441,"with_other"));
@field #10441 = with_slat : @tell("%#","You attach two slats together and create... a bigger slat! That was useful. Not."); @tellroom(@location("%#"),"%#","%n attaches two slats together and creates... a bigger slat! That was useful. Not."); @call(10633,"each_turn");
@field #10441 = with_hoop : @move(10305,"%#"); @tell("%#","You attach a hoop to the end of a slat and create a scooper!"); @tellroom(@location("%#"),"%#","%n attaches a hoop to the end of a slat and creates a scooper!"); @call(10633,"each_turn");
@field #10441 = with_twink : @move(10304,"%#"); @tell("%#","You attach a twink to the end of a slat and create a magic wand!", @tellroom(@location("%#"),"%#","%n attaches a twink to the end of a slat and creates a magic wand!"); @call(10633,"each_turn");
@field #10441 = with_chip : @move(10303,"%#"); @tell("%#","You attach a chip to the end of a slat and create a spear!"); @tellroom(@location("%#"), "%#","%n attaches a chip to the end of a slat and creates a spear!"); @call(10633,"each_turn");
@field #10441 = with_other : @tell("%#","You try to attach the %0 to a slat, but it doesn't seem to make anything useful."); @tellroom(@location("%#"),"%#","%n tries to attach the %0 to a slat, but it doesn't seem to make anything useful."); @call(10633,"each_turn");
===
@open up;u = #10291 @osucc #10270 = swims up to the floating island. @succe #10270 = You swim up to the floating island... @desc #10270 = You see the floating island where you first landed on Gran'boola'woola. @odrop #10270 = swims into view from the depths of the gaseous ocean, to stand again on this island's shore.
The business of getting heavier as you go down was directly inspired by Jota's spacestation, also on the ifMud.
@open down;d = #10266 @odrop #10271 = swims into view, down from the slatosphere. @osucc #10271 = swims down through the slatosphere. @succe #10271 = As you swim downwards, you feel yourself getting a bit heavier... @desc #10271 = Below the slatosphere is the hooposphere.
@open west;w = nowhere
@succe #10272 = @tell("%#","You explore the slatosphere, but don't find
anything new."); @call(10633,"each_turn");
@osucce #10272 = swims away to the west, only to return shortly thereafter.
@desc #10272 = Slats, slats, and more slats, as far as the eye can see.
@open east;e = nowhere
@succe #10273 = @tell("%#","You explore the slatosphere, but don't find
anything new."); @call(10633,"each_turn");
@osucce #10273 = swims away to the east, only to return shortly thereafter.
@desc #10273 = Slats, slats, and more slats, as far as the eye can see.
@dig Hooposphere
@zone #10266 = #10719
@desc #10266 = @tell("%#","You are floating amongst an atmospheric band
full of hoops. All the circles and rings you could ever want.");
@call(10633,"each_turn");
@field #10266 = each_turn :
@switch(@getfield(10266,"pulse"), 0,@setfield(10266,"pulse",1),
1,@setfield(10266,"pulse",2),@print(
@setfield(10266,"pulse",0),
@tellroom(10266,"",@switch(@rand(3),
0,"%cOne hoop spins lazily through the center of another hoop.",
1,"%cTwo nearby hoops bounce off each other like bumper cars.",
2,"%c'A wheel within a wheel a'rollin', way in the middle of the air...'"
))));
@create hoops;circles;circlets;rings;hoop;circle;circlet;ring
@field #10286 = reset : @move(10286,10266);
@zone #10286 = #10719
@desc #10286 = @tell("%#","Hoops appear to be elemental in nature. They
come in many different sizes, but they all appear to be perfectly round
hollow circles or rings."); @call(10633,"each_turn");
@succ #10286 = @tell("%#","You gather and take a scoopful of hoops.");
@call(10633,"each_turn");
@osucc #10285 = gathers and takes a scoopful of hoops.
@drop #10286 = @tell("%#","You drop your scoopful of hoops.");
@call(10633,"each_turn");
@odrop #10286 = drops a scoopful of hoops.
@open up;u = #10265 @odrop #10274 = swims into view, up from the hooposphere. @osucc #10274 = swims up through the hooposphere. @succe #10274 = As you swim upwards, you feel yourself getting a bit lighter... @desc #10274 = Above the hooposphere is the slatosphere.
@open down;d = #10267 @odrop #10275 = swims into view, down from the hooposphere. @osucc #10275 = swims down through the hooposphere. @succe #10275 = As you swim downwards, you feel yourself getting somewhat more heavy... @desc #10275 = Below the hooposphere is the twinkosphere.
@open west;w = nowhere
@succe #10276 = @tell("%#","You explore the hooposphere, but you seem to
be going in circles."); @call(10633,"each_turn");
@osucce #10276 = swims away to the west, only to return from the east.
%s must be going in circles.
@desc #10276 = Hoops, hoops, and more hoops, as far as the eye can see.
@open east;e = nowhere
@succe #10277 = @tell("%#","You explore the hooposphere, but you seem to
be going in circles."); @call(10633,"each_turn");
@osucce #10277 = swims away to the east, only to return from the west.
%s must be going in circles.
@desc #10277 = Hoops, hoops, and more hoops, as far as the eye can see.
@dig Twinkosphere
@zone #10267 = #10719
@desc #10267 = @tell("%#","It's... full of stars!%cYou are floating in
an atmospheric band of... stars? They don't look like real stars; they
look like the five-pointed representations of stars. They still twinkle,
though, so let's call them twinks, okay?"); @call(10633,"each_turn");
@field #10267 = each_turn :
@switch(@getfield(10267,"pulse"), 0,@setfield(10267,"pulse",1),
1,@setfield(10267,"pulse",2),@print(
@setfield(10267,"pulse",0),
@tellroom(10267,"",@switch(@rand(3),
0,"%cLike a miniature meteor shower, a handful of twinks falls in the distance.",
1,"%cThe twinkling of the twinks appears almost magical.",
2,"%cTwinkle, twinkle, little star. How I wonder what you are..."
))));
@create twinks;stars;twink;star
@field #10287 = reset : @move(10287,10267);
@zone #10287 = #10719
@desc #10287 = @tell("%#","Twinks appear to be elemental in nature. They
come in many different sizes, but they all appear to be five-pointed
stars. And twinkly."); @call(10633,"each_turn");
@succ #10287 = @tell("%#","You gather and take a jumble of twinks.");
@call(10633,"each_turn");
@osucc #10287 = gathers and takes a jumble of twinks.
@drop #10287 = @tell("%#","You drop your jumble of twinks.");
@call(10633,"each_turn");
@odrop #10287 = drops a jumble of twinks.
@open up;u = #10266 @odrop #10278 = swims up into view, up from the twinkosphere. @osucc #10278 = swims up through the twinkosphere. @succe #10278 = As you swim upwards, you feel yourself getting somewhat more light. @desc #10278 = Above the twinkosphere is the hooposphere.
@open down;d = #10268 @odrop #10279 = swims into view, down from the twinkosphere. @osucc #10279 = swims down through the twinkosphere. @succe #10279 = As you swim downwards, you feel yourself getting much heavier... @desc #10279 = Below the twinkosphere is the chiposphere.
@open west;w = nowhere
@succe #10280 = @tell("%#","You explore the star-studded twinkosphere,
but find nothing new."); @call(10633,"each_turn");
@osucc #10280 = explores the star-studded twinkosphere to the west, but
returns in a twinkling.
@desc #10280 = Twinks, twinks, and more twinks, as far as the eye can see.
@open east;e = nowhere
@succe #10281 = @tell("%#","You explore the star-studded twinkosphere,
but find nothing new."); @call(10633,"each_turn");
@osucc #10281 = explores the star-studded twinkosphere to the east, but
returns in a twinkling.
@desc #10281 = Twinks, twinks, and more twinks, as far as the eye can see.
@dig Chiposphere
@zone #10268 = #10719
@desc #10268 = @tell("%#","Chips ahoy! You are floating in an atmospheric
band of chips, which are triangles of all shapes and sizes, most of which
have sharp edges and even sharper points. Fortunately for you, they're
spaced out enough so you're not likely to accidently cut yourself moving
around down here."); @call(10633,"each_turn");
@field #10268 = each_turn :
@switch(@getfield(10268,"pulse"), 0,@setfield(10268,"pulse",1),
1,@setfield(10268,"pulse",2),@print(
@setfield(10268,"pulse",0),
@tellroom(10268,"",@switch(@rand(3),
0,"%cA chip floats a bit too close, you manuever out of its way.",
1,"%cSome nearby chips jostle together, startling you.",
2,"%cThe glints of the chips distract you, as they slowly tumble and catch the light."
))));
@create chips;triangles;wedges;chip;triangle;wedge
@field #10288 = reset : @move(10288,10268);
@zone #10288 = #10719
@field #10288 = eat : @tell("%#","They're not the kind of chips you can
eat. These are more like arrowheads."); @call(10633,"each_turn");
@desc #10288 = @tell("%#","Chips appear to be elemental in nature. They
come in many different sizes, but they all appear to be solid isosceles
triangles, or wedges, with sharp points."); @call(10633,"each_turn");
@succ #10288 = @tell("%#","You gather and take a collection of chips.");
@call(10633,"each_turn");
@osucc #10288 = gathers and takes a collection of chips.
@drop #10288 = @tell("%#","You drop your collection of chips.");
@call(10633,"each_turn");
@odrop #10288 = drops a collection of chips.
@open up;u = #10267 @odrop #10282 = swims into view, up from the chiposphere below. @osucc #10282 = swims up through the chiposphere. @succe #10282 = As you swim upwards, you feel yourself getting much lighter. @desc #10282 = Above the chiposphere is the twinkosphere, almost like a different reality.
@open down;d = #10294 @odrop #10295 = falls out of the chiposphere, and makes a safe, if undignified, landing. @osucc #10295 = swims down through the chiposphere, and rather quickly, too. @succe #10295 = As you swim downwards, you feel yourself getting significantly heavier... Too heavy! You're falling!!%caaahhhhh!!!!%c---- @desc #10295 = You can see something like land below you!
@open west;w = nowhere
@succe #10283 = @tell("%#","You swim amongst the chips, but find nothing
new. Not even a chip on your shoulder."); @call(10633,"each_turn");
@osucc #10283 = swims westward for a bit, then angles back.
@desc #10283 = Chips, chips, and more chips, as far as the eye can see.
@open east;e = nowhere
@succe #10284 = @tell("%#","You swim amongst the chips, but find nothing
new. Not even a chip on your shoulder."); @call(10633,"each_turn");
@osucc #10284 = swims eastward for a bit, then angles back.
@desc #10284 = Chips, chips, and more chips, as far as the eye can see.
Der Stinkle's name comes from Beanworld, but there it was the underground home of an insect race, far below the four realities. Here, it gets its name because the Filth used to live here. The Filth are one of the actual alien races from the Cosmic Encounter game.
@dig Der Stinkle @zone #10294 = #10719 @desc #10294 = Phew!! To put it mildly, this place reeks!! This must be an abandoned base of the aliens known as the Filth; there's garbage and debris everywhere. The smell of the Filth themselves is so bad that no other alien race will willingly stay on the same planet with them. Logically, this place must've been fumigated after they left, but... oh gawd, the smell is awful! You've got to get out of here, or the smell alone is going to kill you! @field #10294 = smell : Ugh, you're trying not to. Really. Even without trying, you can smell sulphur, ketchup, ammonia, what must've been an alien's outhouse, fungus, and broccoli.
From Beanworld again. They are actually insect eggs, but the Beans don't actually know that.
@create mystery pods;insect eggs;mp;pods;eggs
@set #10289 = expert
@set #10289 = slippery
@field #10289 = reset : @move(10289,10294);
@zone #10289 = #10719
@desc #10289 = @tell("%#","The mystery pods are small and round, roughly
the size of baseballs. The pods come in different colors - gray, white,
or brown - and have a shiny lustre, like pearls. You don't know if they
are stones, pearls, eggs, capsules, or what. They're a mystery.");
@call(10633,"each_turn");
@succ #10289 = @tell("%#","You pick up a handful of the mystery pods.");
@call(10633,"each_turn");
@osucc #10289 = picks up a handful of the mystery pods.
@drop #10289 = @tell("%#","You drop the mystery pods.");
@call(10633,"each_turn");
@odrop #10289 = drops the mystery pods.
The secret of "float factor" is to put twinks on mystery pods. Just as the comic book on the Red StarDisc said.
@action put * on pods;put * on pod;place * on pods;
place * on pod = mystery pods : nowhere
@set #10431 = puzzle
@succe #10431 = @switch(@object("%#","%0"), "10287", @print( "You put a
couple twinks on the pods, and a startling metamorphosis takes place!
The pods begin to twinkle... ", @tellroom(@location("%#"),"%#","%n puts a
couple twinks on the pods, and a startling metamorphosis takes place!
The pods begin to twinkle... "), @switch(@location("10289"),"%#",@print(
"slip out of your startled hands... ", @tellroom(@location("%#"),"%#",
"slip out of %p hands... "))), "and float into the air! The twinkly pods
are now floating several feet above your head. You have discovered the
secret float factor!", @tellroom(@location("%#"),"%#","and float into
the air! The twinkly pods float several feet above you. %n has discovered
the secret float factor!"), @move("10297",@location("%#")),
@move("10289","9671")), "-1", "Put what on the pods? You're not carrying
that, are you?", @print( "You put the %0 on the pods, but nothing
happens.", @tellroom(@location("%#"),"%#", "%n tries putting %0 on the
pods, but nothing happens.")));
@desc #10431 = Try putting something on the pods.
The filthy debris hides the only reason you'd want to visit Der Stinkle: the lost program card. Search the debris to find it.
@create filthy debris;debris;garbage;fd
@field #10298 = search : @switch(@location("10164"),"11718",@print(
"Holding your nose, you search the filthy debris and find a program card,
which you take.", @tellroom(@location("%#"),"%#","%n searches the filthy
debris and finds a program card, which %s takes."), @move("10164","%#")),
@print( "Holding your nose, you search the filthy debris, but find nothing
useful.", @tellroom(@location("%#"),"%#","%n searches the filthy debris,
but finds nothing useful."))); @call(10633,"each_turn");
@lock #10298 = -1
@zone #10298 = #10719
@desc #10298 = @tell("%#","It's yucky and gross, okay? Between the
glatorp stains here and diseased kinzosh there, there could be anything
in this kingdom of putrid squalor."); @call(10633,"each_turn");
@fail #10298 = @tell("%#","You have no desire to take the filthy debris.
Not all of it, anyway."); @call(10633,"each_turn");
@field #10298 = smell : UGH! No way!
This card is one of the two "treasures" of the red system (the other is the golden apple). It's used to reprogram the Food-a-Rac-a-Cycle at the spaceport.
@create program card;program;card;pc
@field #10164 = reset : @move("10164","11718");
@zone #10164 = #10719
@desc #10164 = @tell("%#","This is a program card, a thin wafer of
electronics with a computer program on it. Its label says \"Key
program\", and there's a manufacturer's mark in one corner: \"FaRaC\".");
@call(10633,"each_turn");
@succ #10164 = @tell("%#","You pick up the program card.");
@call(10633,"each_turn");
@osucc #10164 = picks up the program card.
@drop #10164 = @tell("%#","You drop the program card.");
@call(10633,"each_turn");
@odrop #10164 = drops a program card.
Oops! Der Stinkle is at the bottom of a gravity well! If you picked up slats and hoops and twinks on your way here, you can harness the power of "float factor" to escape. Otherwise you'll have to "pray".
@open up;u = #10268 @lock #10296 = -1 @ofail #10296 = tries to swim back up into the upper layers, but falls back down. @fail #10296 = You try to swim back up to the upper layers, but the gravity of the planet is just a bit too much, and you fall back down. Pity you don't know how to fly. @desc #10296 = The upper reaches of the atmosphere are, alas, currently out of reach.
Der Stinkle can be a dead-end if you're missing crucial stuff, so "pray" is here so you're not forced to "xyzzy" or "lounge" outta here. However, you lose the program card if you pray yourself out of this fix, because you failed to solve the puzzle. (Incidently, if you're wondering why prayer works at all, it's because of the Elder. He's the one who actually saves you.)
@open pray = #10291
@succe #10735 = @tell("%#","You pray for deliverance from this malodorous
wasteland. For a moment, nothing happens. Then, you think you feel another
mind touch yours... the fumes must be getting to you...");
@switch(@location(10297),"%#",@move(10297,11718));
@switch(@location(10289),"%#",@move(10289,10294));
@switch(@location(10164),"%#",@move(10164,11718));
@setfield(10291,"ispray_%#",1);
@osucc #10735 = disappears between one blink and the next. You didn't see
how %s left.
@desc #10735 = Well, a prayer couldn't hurt, and it might help.
// @move("%#",10291);
// @tell("%#","Huh? What just happened? How'd you get back here?
// Are you still carrying everything you had?");
// @tellroom(10291,"%#","Huh? You didn't notice how %n arrived, but %s's
here now.");
@create twinkly pods;float factor;pods;tp
@set #10297 = expert
@ofail #10297 = tries to grab the twinkly pods, but can't quite reach them.
@fail #10297 = @tell("%#","You can't quite reach the pods. You need to
have a butterfly net, or something similar."); @call(10633,"each_turn");
@field #10297 = reset : @move(10297,11718);
@osucc #10297 = scoops up the twinkly pods with a newly-made scooper.
@lock #10297 = #10305
@succe #10297 = @tell("%#","You manage to scoop up the twinkly pods with
your handy scooper.%cGreat. Let's review:%c[1] You're got twinkly pods,
which can fly. Check.%c[2] You're in Der Stinkle, a place that can only
be escaped by flying. Check.%cSo... the way to escape Der Stinkle is with
the pods. But how?");@call(10633,"each_turn");
@zone #10297 = #10719
@desc #10297 = @tell("%#","The twinkly pods are floating in mid-air! They
also have a new texture. Sort of out-of-focus, and sort of like corduroy.
It's hard to define precisely. Disjointed twinks float and flicker about
the twinkly pods."); @call(10633,"each_turn");
For once, more is indeed better. If a few twinks get the pods to float a little, then more twinks will make them float a lot! And carry you outta Der Stinkle, assuming you're holding onto the pods, that is.
@action put * on pods;place * on pods;put * on twinkly pods;
place * on twinkly pods;put * on tp;place * on tp = twinkly pods : nowhere
@set #10474 = puzzle
@succe #10474 = @switch(@object("%#","%0"),
"10287", @switch(@location("10297"),"%#", @print(
@move("10287","10267"), @move("10297","11718"), @move("10305","11718"),
@move("10289","10294"), @tell("%#","You put the rest of the twinks on
the already twinkly pods, and they zoom upwards, carrying you with
them! You fly up through all four layers of gases... and you're not
stopping! In a panic, you release the scooper before you're dragged
into the vacuum of space and watch the pods travel onward, ever
onward, to an unknown destiny in the stars. You then spot the
floating island nearby, and swim back over to it. *whew*"),
@move("%#","10291"), @tellroom("10294","%#","%n puts more twinks on
the twinkly pods, and they zoom upwards, carrying %o with them!
%cUnnoticed amongst the debris, you see more mystery pods here."),
@tellroom("10291","%#","Suddenly, %n flies up into view from below,
dragged by... something twinkling in a butterfly net?? %S releases the
net, or whatever it was as it flies off, and swims back to the island.")),
"Um, you *really* want to be holding the twinkly pods before trying that."),
"-1", "Put what on the pods? You're not carrying that, are you?",
@print( "You put the %0 on the pods, but nothing happens.",
@tellroom(@location("%#"),"%#", "%n tries putting %0 on the pods, but
nothing happens.")));
The only use for the spear here is to throw it at the apple. In the Beanworld, spears were used by the Beans in chowraids vs. the Hoi Polloi.
@create spear;weapon;trusty spear;ts
@set #10303 = expert
@field #10303 = reset : @move(10303,11718);
@zone #10303 = #10719
@desc #10303 = @tell("%#","You made this trusty spear by putting a chip
onto the end of a slat."); @call(10633,"each_turn");
@succ #10303 = @tell("%#","You pick up the spear.");
@call(10633,"each_turn");
@osucc #10303 = picks up the spear.
@drop #10303 = @tell("%#","You drop the spear.");
@call(10633,"each_turn");
@odrop #10303 = drops a spear.
@action throw spear at *;toss spear at * = spear : nowhere
@set #10480 = puzzle
@succe #10480 = @switch(@object(@location("%#"),"%0"), "-1",
"You don't see any %0s here.",
"10475", @print("You hurl the spear at the golden apple. It's a perfect
toss! The spear pierces the apple, and they both fall into your hands.
\"Great shot!\" exclaims the not-really-an-apple.",
@tellroom(@location("%#"),"%#","%n hurls %p spear at the golden apple.
It's a perfect toss! The spear pierces the apple, and they both fall
into %p hands. \"Great shot!\" exclaims the not-really-an-apple."),
@move("10475","%#"), @setfield("10475","lock",""),
@setfield("10475","ontree",""), @setflag("10475","!dark")),
"The %4 is not an appropriate target for your spear.");
The only use for the scooper here is to grab the twinkly pods when they're floating high above you. In Beanworld, the Beans used scoopers to carry chow or water.
@create scooper
@field #10305 = reset : @move(10305,11718);
@zone #10305 = #10719
@desc #10305 = @tell("%#","This scooper was made by putting a hoop onto
the end of a slat. It's just the thing for grabbing stuff that would
otherwise be out of reach."); @call(10633,"each_turn");
@succ #10305 = @tell("%#","You pick up the scooper.");
@call(10633,"each_turn");
@osucc #10305 = picks up the scooper.
@drop #10305 = @tell("%#","You drop the scooper.");
@call(10633,"each_turn");
@odrop #10305 = drops a scooper.
The magic wand is used to disassemble stuff you've put together here; for example, you can split the spear back into a slat and a chip. In Beanworld, Professor Garbanzo did create a wand out of a slat and twink, but it didn't do anything useful.
@create magic wand;wand;rusty wand;mw
@set #10304 = expert
@field #10304 = reset : @move(10304,11718);
@zone #10304 = #10719
@desc #10304 = @tell("%#","This magic wand was made by putting a twink
onto the end of a slat.");@call(10633,"each_turn");
@succ #10304 = @tell("%#","You pick up the magic wand.");
@call(10633,"each_turn");
@osucc #10304 = picks up the magic wand.
@drop #10304 = @tell("%#","You drop the magic wand.");
@call(10633,"each_turn");
@odrop #10304 = drops a magic wand.
@action wave wand at *;point wand at * = magic wand : nowhere
@set #10478 = puzzle
@succe #10478 = @switch( @switch(@object(@location("%#"),"%0"), "-1",
@object("%#","%0"), @object(@location("%#"),"%0")), "-1", "You don't see
that here.", "10304", "You can't wave the wand at itself!", "10297",
@print("You wave the wand at the twinkly pods, and the twinks fall off
them into your hands. The pods, no longer flying or twinkly, fall into
your hands as well.", @tellroom(@location("%#"),"%#", "%n waves %p wand
at the twinkly pods, and the twinks fall off them into %p hands. The pods,
no longer flying or twinkly, fall into %p hands as well."),
@move(10289,"%#"), @move(10287,"%#"), @move(10297,11718)),
"10303", @print("You wave the wand at the spear, and it splits apart into
a chip and a slat, which you take.", @tellroom(@location("%#"),"%#",
"%n waves %p wand at the spear, and it splits apart into a chip and a
slat, which %s takes."), @move(10288,"%#"), @move(10285,"%#"),
@move(10303,11718)), "10305", @print("You wave the wand at the scooper,
and it splits apart into a hoop and a slat, which you take.",
@tellroom(@location("%#"),"%#", "%n waves %p wand at the scooper, and it
splits apart into a hoop and a slat, which %s takes."),
@move(10286,"%#"), @move(10285,"%#"), @move(10305,11718)),
"%#", @print("You wave the wand at yourself, but nothing happens.",
@tellroom(@location("%#"),"%#", "%n waves %p wand at %oself, but nothing
happens.")), @print("You wave the wand at %4, but nothing happens.",
@tellroom(@location("%#"),"%#", "%n waves %p wand at the %4, but nothing
happens."))); @call(10633,"each_turn");