Source text for Release 1 of Easter Egg Hunt 2020

A thing can be important or unimportant. A thing is usually unimportant.

[Portable tools must be important to start with but lose their importance later!

Explain for every inventory item how we'll deal with their importance!!

* Aqua's urn(s): It's unimportant when the Umber egg found and everything else important is not in Aqua-Grave.

* Cancer's hat(s): It's never important.

* Cap's goat: It's always important.

* Leo's sack/sock: It's important while it has anything important in it.

* Leo's speckled egg: it's always important.

* Libra's cube(s): It's usually important; it is only unimportant when on a scale-pan.

* Pisces' popcorn/pretzels: It becomes unimportant after it's used.

* Sag's bow/crossbow: It becomes unimportant after it's used.

* Sag's arrow/arrowhead: It becomes unimportant after it's used.

* Scorp's rag(s): It becomes unimportant after it's used to clean the muck.

* Virgo's moon/sun key: It becomes unimporant once the Navy egg appears.

* Virgo's book(s): It's always important.

* Virgo's paper(s): It becomes unimportant once the Navy egg appears.

* Gemini: nothing new.

* Aries: technically nothing new.

* Taurus: nothing new.

]

A thing can be distant or near. A thing is usually near.

Instead of doing something other than examining or shooting with a distant thing:

say "[The noun] is too far away."

A thing has a thing called the alter-ego. [The default value is yourself. Icky, but we can work with that.]

A clock-hand is a kind of thing. A clock-hand has a number called the numeric setting.

An easter-egg is a kind of thing. An easter-egg is always important.

A balance-coin is a kind of thing. Understand "coin" as a balance-coin. The description of a balance-coin is usually "A round unstamped disc, presumably part of the local currency."

A gold-coin is a kind of balance-coin. Understand "gold" or "gold coin" as a gold-coin. The printed name is "gold coin".

Rule for printing the plural name of a gold-coin: say "gold coins".

A bronze-coin is a kind of balance-coin. Understand "bronze" or "bronze coin" as a bronze-coin. The printed name is "bronze coin".

A scale-pan is a kind of supporter. A scale-pan is always scenery. Understand "pan", "side", or "tray" as a scale-pan.

Before putting something on a scale-pan:

if the noun is a balance-coin or the noun is an easter-egg or the noun is the featureless white cube or the noun is the featureless black cube:

continue the action;

else:

instead say "The pans gleam with what almost seems greed, and somehow they contrive to nudge your hand past them with your worthless and boring item."

Understand "set [clock-hand] to [number]" as setting it by number. Setting it by number is an action applying to one thing and one number.

Instead of setting a clock-hand to something:

say "You can only set [the noun] to a number from 1 to 12."

Check setting a clock-hand by number:

if the number understood is less than 1 or the number understood is greater than 12:

instead say "The clock dial only has numbers from 1 to 12."

Carry out setting a clock-hand by number:

now the numeric setting of the noun is the number understood.

Report setting a clock-hand by number:

say "You set [the noun] to [number understood]."

Quivvering is an action applying to nothing. Understand "quivver" or "say quivver" or "cast quivver" as quivvering.

Report quivvering:

if the player is in Sag-Region:

say "That was magic all right - the Phil can tell from the twitching of his ponytail - but power is lacking, and nothing happens.";

else:

say "Nothing happens."

Crediting is an action out of world. Understand "credits" or "about" as crediting.

Report crediting:

say "[bold type]Easter Egg Hunt 2020[roman type] was written by me, David Welbourn, in the week from the end of the ClubFloyd session on Sunday April 5th to sometime before the ClubFloyd session on Easter Sunday April 12th, 2020. It was one of those just-for-fun projects.

However, it should be obvious that this is not just my own work by any means. It includes many bits and pieces from other interactive fiction games by other authors, which I quickly stitched together into this crazy quilt of a game. Hopefully it holds together without falling apart into a huge mess.

The works of IF that I, uh, pillaged for this game are:[line break]* [italic type]Balances[roman type] by Graham Nelson.[line break]* [italic type]Best Gopher Ever[roman type] by Arthur DiBianca.[line break]* [italic type]Birmingham IV[roman type] by Peter Emery.[line break]* [italic type]A Boy and his Goat[roman type] by Ola Sverre Bauge.[line break]* [italic type]Cragne Manor[roman type] by many authors and organized by Jenni Polodna and Ryan Veeder; the part I'm reusing is the Cragne Family Plot by Mark Britton.[line break]* [italic type]Grayscale[roman type] by Daniel T. Freas.[line break]* [italic type]The Homework of Little Carl Gauss[roman type] by Stefano Gaburri.[line break]* [italic type]Krakatoa Tuna Melt[roman type] by David Welbourn.[line break]* [italic type]Maiden of the Moonlight[roman type] by Brian P. Dean.[line break]* [italic type]Oh No, Mr Crab Stole Your Hat![roman type] by Brown Cow.

Testing for Release 1 was done just by me. How foolish I am! Always get other people to test your work!

I must also admit that several of the borrowed locations had to be flipped around or turned sideways to fit into my new geography, and several borrowed items were also altered to fit into the new storyline or puzzles. Sometimes I simplified things to make it easier for myself or for the player. Regardless, this game has major spoilers for the smallest games I borrowed from, and minor spoilers for the larger games.

Please enjoy this mess! It should be a pretty easy game for most of you, but if not, please let me know!"

Understand "fish" as a mistake ("You'll never need to go fishing in Easter Egg Hunt 2020.").

Swimming is an action applying to nothing. Understand "swim" as swimming.

Report swimming:

say "There's nowhere suitable to swim here."

Filling is an action applying to one thing. Understand "fill [something]" as filling.

Report filling something:

if the player is in Aqua-Region:

say "You don't want to dirty [the noun] with corpse water. Maybe something more funereal would work?";

if the noun is a container:

say "You can't fill [the noun] here.";

else:

say "You can't fill [the noun]."

Bailing is an action applying to one thing. Understand "bail [something]" or "empty [something]" as bailing.

Report bailing something:

say "You can't bail that."

Digging is an action applying to nothing. Understand "dig" as digging.

Report digging:

say "You can't dig here."

Thing-digging is an action applying to one thing. Understand "dig [something]" as thing-digging.

Report thing-digging:

say "You can't dig that."

Before taking inventory:

sort the basket;

continue the action.

Understand "rest" as sleeping.

Clockwise is a direction. The opposite of clockwise is counterclockwise. Understand "c" or "cw" as clockwise.

Counterclockwise is a direction. The opposite of counterclockwise is clockwise. Understand "cc" or "ccw" as counterclockwise.

Rim-region is a region.

Clocky-dirs-mentioned is a truth state that varies. Clocky-dirs-mentioned is false.

Every turn when clocky-dirs-mentioned is false and the player is in Rim-region:

now clocky-dirs-mentioned is true;

say "[italic type][bracket]By the way, when at the edge of the Big Lawn, at one of these 'O'Clock' locations, you can also use C or CW (for clockwise) and CC or CCW (for counterclockwise) to circle around the Lawn. -- DW[close bracket][roman type][paragraph break]".

When play begins:

say "'Welcome, welcome, welcome to my new game! It's very simple. All you have to do is pick up that basket, fill it with a dozen Easter eggs and put it on that pedestal there. And there might be one little puzzle at the end, just to see if you've been paying attention.[paragraph break]'Oh, and I should mention that most of the puzzle scenarios have been cribbed from other interactive fiction games! Oo, [italic type]nostalgia[roman type]. I get the warm fuzzies just thinking about it. Such fun we're going to have!'[paragraph break]Um. Who said that?"

CenterRoom is a room. The printed name is "Center of the Big Lawn". The description is "Here, at the center of the Big Lawn, a rose marble pedestal stands self-importantly. Dirt paths lead north, south, east, and west through the well-manicured grass. From here, you can see that the outer edge of the Big Lawn is surrounded by twelve archways like the points of a clock."

A straw basket is an open important container in CenterRoom. The alter-ego is the straw bucket.

Check inserting something into the straw basket:

if the noun is not an easter-egg:

say "Sorry, but only Easter eggs belong in the straw basket." instead.

Before examining the straw basket:

sort the basket;

continue the action.

Some grass is scenery in CenterRoom. "The grass is such a vibrant shade of green, it practically glows.[paragraph break][italic type][bracket]Feel free to walk on the grass. You don't have to stay on the dirt paths. -- DW[close bracket][roman type]".

Understand "walk on grass","walk on the grass" as a mistake ("You'll have to say which compass direction to go in.").

A rose marble pedestal is a scenery supporter in CenterRoom. The description is "The top of the pedestal is inscribed with the message: 'Put your basket full of Easter eggs here',"

Instead of putting the basket on the rose marble pedestal:

sort the basket;

if the number of easter-eggs in the basket is 0:

say "The pedestal reacts to your empty basket with a sad trombone noise. Embarrassed, you take the basket back.";

else if the number of easter-eggs in the basket is less than 4:

say "The pedestal reacts to your nearly-empty basket with a mocking kazoo whistle. You can do better than that, you think, as you take the basket back.";

else if the number of easter-eggs in the basket is less than 7:

say "The pedestal reacts to your modest collection of eggs with polite applause, but that's it. Hmmm. You take the basket back. Let's find some more eggs.";

else if the number of easter-eggs in the basket is less than 10:

say "The pedestal reacts to your more-than-half-full basket with some stirring music as if it's half time at a sporting event. That's encouraging. You take the basket back, eager to find the rest of the eggs.";

else if the number of easter-eggs in the basket is less than 12:

say "The pedestal reacts to your nearly-full basket with a brief musical flourish and loud applause. Gratifying, but since nothing else happens, you take the basket back. Need! More! Eggs!";

else if the number of easter-eggs in the basket is 12:

say "The pedestal reacts to your full basket with twelve DINGs! followed by an elaborate fanfare! Trumpets! Cheering! Gold and silver confetti falling from the open sky! You are so distracted trying to see where the confetti is coming from that you almost miss the pink fog emanating from the lawn until it completely surrounds you![paragraph break]* * *[paragraph break]But before you have time to panic, the cloud quickly dissipates, the music and cheering dies down, and now you, the pedestal, and the basket of eggs are now somewhere else...";

now the basket is on the rose marble pedestal;

now the basket is fixed in place;

now the rose marble pedestal is in Room13;

now the player is in Room13.

Instead of putting an easter-egg on the rose marble pedestal:

say "[The noun] starts rolling off. You quickly take it back before it can fall."

Instead of putting something on the rose marble pedestal:

say "[The noun] starts sliding off. You quickly take it back before it can fall."

Room4 is south from Room3. Room4 is clockwise from Room3. Room4 is in Rim-region. The printed name is "4 O'Clock". The description is "You're at the east-by-southeast edge of the Big Lawn. Dirt paths go southwest and north, and [if arch4 is open]an open archway beckons[else]a closed archway is[end if] to the east."

An arch4 archway is an open unopenable scenery door. It is east from Room4. It is west from Cancer-LivingRoom. The printed name is "archway". Understand "portcullis" as arch4 when arch4 is closed. The description of arch4 is "[if player is in Cancer-LivingRoom]The open archway leads west back to the Big Lawn[else if arch4 is open]The open archway leads east into your living room[else]The archway is now barred with a portcullis since you have taken everything you need from Mr Crab[end if]."

Before going east from Room4 when arch4 is open:

say "This section is based on all of[line break][bold type]Oh No, Mr Crab Stole Your Hat![roman type][line break]An Interactive Hat Hunt by Brown Cow.";

continue the action.

Cancer-Region is a region. Cancer-LivingRoom, Seaside Cottage, Cancer-Path, and Cancer-Beach are in Cancer-Region.

Every turn when the player is in Room4:

if arch4 is open:

if the number of important things in Cancer-Region is 0 and the Puce egg is not nowhere:

now arch4 is closed;

now arch4 is locked;

say "A portcullis falls down inside the archway, blocking your way back to the living room."

Cancer-LivingRoom is a Room. The printed name is "Living Room". The description is "Your cosy living room is inhabited by a plump brown sofa and your desk in the corner. To the east is that crab. Or at least you hope so. He better not be scuttling around your house. To the west is an archway you've never seen before."

A plump brown sofa is in Cancer-LivingRoom. It is scenery.

Instead of searching the plump brown sofa:

say "Your hat isn't on, in, under, or behind the unimplemented plump brown sofa."

A cancer-desk desk is in Cancer-LivingRoom. The printed name is "desk". It is scenery.

Instead of searching the cancer-desk:

say "Your hat isn't on, in, under, or behind your unimplemented desk."

A front door is an open scenery openable door. It is east from Cancer-LivingRoom and west from Seaside Cottage. The description is "It is blue."

Instead of closing the front door:

say "Why? Does closing a front door keep crabs out of houses?"

Instead of searching the front door:

say "The front door has no crabs or hats hiding anywhere near it. Did I mention it was blue? Because it is. It is blue."

Seaside Cottage is a Room. The description is "You stand right next to your front door. There is a short path to the northeast."

Sir Syd is a scenery animal in Seaside Cottage.

Every turn when the player is in Seaside Cottage:

if Sir Syd is in Seaside Cottage:

now Sir Syd is in Cancer-Path;

say "That annoying Mr Crab Lord Sir Syd scuttles quickly down the path. Did he have your hat in his claw?!".

Every turn when the player is in Cancer-Path:

if Sir Syd is in Cancer-Path:

now Sir Syd is nowhere;

say "Yes! That lousy Lord Sir Syd Mr Crab is stealing your hat! He's heading for the beach!"

Cancer-Path is northeast of Seaside Cottage. The printed name is "Path". The description is "The finely cobbled path streches on for a little longer, to the northeast, and ends up at the beach."

Cancer-Beach is northeast of Cancer-Path. The printed name is "Beach". The description is "You can see a small rockpool here, with some rocks beside it. You don't see that crab."

Instead of swimming when the player is in Cancer-Beach:

say "It's far too early in the year for swimming outside."

A small rockpool rock pool rocks is scenery in Cancer-Beach. The printed name is "small rockpool".

Instead of doing something with the rockpool:

say "The small rockpool itself is of no interest to you whatsoever."

A top hat is a wearable thing in Cancer-Beach. The initial appearance is "But on one of the rocks is - wait for it - your hat!" The description is "You see nothing special about the top hat.[paragraph break]Except it's yours, it's your hat, and even a stupid crab ought to know that.". The alter-ego is the bowler hat.

A Puce egg is an easter-egg. The description is "It's a pretty Easter egg in that grandmotherly purple color that can only be called Puce. There's a subtle pattern to it that even looks like knitting. And a small number '4' is stamped on one end. You wonder who Mr Crab stole this egg from before you stole it from him."

Instead of taking the top hat when the top hat is in Cancer-Beach:

now the player wears the top hat;

say "You triumphantly perch your hat on your head and, as an afterthought, pick up the Puce egg that was cunningly concealed underneath[if the player carries the basket]. You put the Puce egg into your basket[end if].[paragraph break]You beat Crab Sir Syd Lord! Yay![paragraph break]You should go back to the Big Lawn now.";

if the player carries the basket:

now the Puce egg is in the basket;

else:

now the player carries the Puce egg.

Room5 is southwest from Room4. Room5 is clockwise from Room4. Room5 is south from Room1. Room5 is in Rim-region. The printed name is "5 O'Clock". The description is "You're at the south-by-southeast edge of the Big Lawn. Dirt paths go west and northeast, and [if arch5 is open]an open archway beckons[else]a closed archway is[end if] to the south."

An arch5 archway is an open unopenable scenery door. It is south from Room5. Through it is Veldt. The printed name is "archway". Understand "portcullis" as arch5 when arch5 is closed. The description of arch5 is "[if arch5 is open]The open archway leads south onto a African veldt[else]The archway is now barred with a portcullis since you have taken everything you need from the nursery[end if]." [Note: the arch5 archway IS NOT also in the Veldt. This archway is a one-way door!]

Before going south from Room5 when arch5 is open:

now nursery setting is 1;

say "This section is adapted from quite a lot of[line break][bold type]The Homework of Little Carl Gauss - IntroComp04 Preview Version[roman type][line break]A dimension-traveling adventure with sound, no mazes, no darkness, and a bagful of cats! By Stefano Gaburri.";

continue the action.

Leo-Region is a region. Veldt, Cramped Lab, Hamlet, Fantasy World, Ship's Cabin, and Dark Dungeon are in Leo-Region.

Every turn when the player is in Room5:

if arch5 is open:

if the number of important things in Leo-Region is 0:

now arch5 is closed;

now arch5 is locked;

say "A portcullis falls down inside the archway, blocking your way back to the nursery."

Veldt is a room. The printed name is "In the Veldt". The description is "[if lions are in Veldt]The sun is a boiling sphere of fire in the blinding sky. All around you the African veldtland stretches to the horizon, pale yellow and dirty white. The rusty smell of the animals mingles your own perspiration while the air seems to become solid in your throat. Not far, in a clearing in the waist-high grass, several lions are walking in circles, looking like ghosts throught the scorching heat.[else]If possibile, the heat seems to have raised. The veldt keeps stretching in all directions, but there are no more lions in sight (whew!). Time to look for someplace fresher...".

Instead of smelling Veldt:

say "How to describe the smell of the veldt? It seems almost as you could taste the very heat of the air. Most of all, however, you nostrils are filled by the savage, musty smell of the lions."

Instead of exiting in Veldt, try going south.

Instead of going north in Veldt:

say "The archway you entered isn't here on this side!".

A leo1portal shimmering portal is a closed unopenable door. It is fixed in place. It is south from Veldt. Through it is Cramped Lab. The printed name is "shimmering portal". The description is "It's a kind of weird portal of shimmering light. On the other side you can make out some faint shapes, but nothing too clear. You wonder if you could pass through."

Instead of touching leo1portal:

say "You finger passes through the shimmering barrier."

Before entering the leo1portal when the leo1portal is closed:

instead say "[one of]You try to cross the shimmering barrier, but for now it seems unpenetrable[or]Given your surroundings, you wish you would[or]Not yet[or]Not yet[cycling].";

Before going south from Veldt:

if the leo1portal is closed:

instead say "[one of]You try to cross the shimmering barrier, but for now it seems unpenetrable[or]Given your surroundings, you wish you would[or]Not yet[or]Not yet[cycling].";

else if the leo1portal is open and Cramped Lab is unvisited:

say "WHEW! What a ride! This simulation is really something... in fact, Scotty (the ship's resident scientist/technician/omnilogist) had warned you not to use the nursery without supervision, but hey - they have gone down on the planet to enjoy themselves, you can have a good time too, huh?[paragraph break]Not half a minute later something strange happens - the transportation pod in the corner starts lighting up and flashing, then it goes dark again. The whole ship starts rocking and humming - it's a ion tempest![paragraph break]The communication system starts up: it's Scotty, from downplanet! But, after a long burst of static, the comm system goes dead silent."

Some lions are scenery animals in Veldt. The description is "The lions are so realistic you wonder if they are indeed mere projections." Understand "lion" as lions.

Instead of attacking the lions:

say "This would be foolish in the first place. Besides, how could you attack some mental projections?".

Instead of touching the lions:

say "If they were real, it would be foolish. Being mere projections, it's plain silly.".

A leo1sun sun is a scenery thing in Veldt. The printed name is "sun". The description is "You don't think any human being could survive long under this sun."

Instead of doing something other than examining with the leo1sun :

say "I wouldn't bother."

A chunk of meat is a scenery thing in Veldt. The description is "It's just a bloody chunk of meat. You think."

Instead of doing something other than examining with the meat:

say "I wouldn't bother."

Lions-Scene is a scene. Lions-Scene begins when the player can see the lions. Lions-Scene ends when the player is in Cramped Lab.

Every turn during Lions-Scene:

if the time since Lions-Scene began is 2 minutes:

say "The lions seem to be disputing a large chunk of meat. You shudder, thinking it was live and kicking just a minute ago.";

if the time since Lions-Scene began is 4 minutes:

say "Now the lions seems to be feeling your presence. How can it be? This should not be possible!";

if the time since Lions-Scene began is 6 minutes:

say "Yellow eyes fix on you. You feel a low growl coming from ferine throats, while the biggest male begins to approach you. By now the air in your throat feels like molten lead... you never thought Africa could feel this real.";

if the time since Lions-Scene began is 8 minutes:

say "You can't help it, your breath quickens. This seems much too real. The lions have encircled you, and the big male seems ready to jump at your throat!";

if the time since Lions-Scene began is 9 minutes:

now the lions are nowhere;

now the leo1portal is open;

say "The portal to the south seems to change in a barely perceptible way, becoming more transparent! Maybe it has finally opened? Before you can step through, the dominant male jump straight at your throat! You almost faint, feeling his fangs rip through your throat.[paragraph break]A second later, the lions have disappeared: you're alone. Sure, it was all a mental projection! It's easy to realize it, now... you mutter to yourself 'this nursery really rocks', wipe the sweat from your brow and get up from the ground (plasteel floor, what else?). Trying to regain your composture, you hope Jack didn't see you from the other side of the portal while you were losing your grip."

Cramped Lab is a room. The description is "This is a simple lab that doubles as a transportation room. After all, this is a small spaceship. To the west there is a corridor leading towards the main bridge and the rest of the living quarters. A door-sized section of the northern wall is occupied by a shimmering wall of light: the portal to the nursery. In the corner there's a medium-sized standard teleportation pod."

Instead of going west in Cramped Lab:

say "You cannot go west: the recent ionic storm has triggered the security systems and the main computer has shut the armored bulkheads."

A leo0portal shimmering portal is in Cramped Lab. It is fixed in place. The printed name is "shimmering portal". The description of leo0portal is "It's a kind of weird portal of shimmering light. On the other side you can make out some faint shapes, but nothing too clear." [Not programming it as a door since I don't know how to make a door in Inform 7 have variable destinations.]

A teleportation pod comm communication system is in Cramped Lab. It is scenery. The printed name is "teleportation pod". The description is "A standard-issue teleportation pod with a built-in communication system. Unfortunately, Scotty never taught you how to use it or fix it."

Nursery setting is a number that varies. Nursery setting is 1.

A nursery console is in Cramped Lab. It is fixed in place. The description is "This is the console that controls the virtual nursery. Scotty preloaded six settings, which you can switch between by setting a dial, but the recent power failure seems to have made the environments unstable. The dial is currently set to '[nursery environment]'."

A dial is part of the nursery console. The description is "The dial has 6 positions. Beside each one there is a tag scribbled with a hasty hand. Now the dial points to a position marked as '[nursery environment]'."

Understand "set [dial] to [number]" as dialling it by number. Dialling it by number is an action applying to one thing and one number.

Instead of setting the dial to something:

say "You can only set [the noun] to a number from 1 to 6."

Check dialling the dial by number:

if the number understood is less than 1 or the number understood is greater than 6:

instead say "The dial only has settings from 1 to 6."

Carry out dialling the dial by number:

now the nursery setting is the number understood.

Report dialling a dial by number:

say "You turn the dial, setting it to '[nursery environment]'."

Instead of turning the dial:

increase the nursery setting by 1;

if the nursery setting is 7:

now the nursery setting is 1;

say "You turn the dial, setting it to '[nursery environment]'."

To say nursery environment:

if nursery setting is 1:

say "1: The African Veldt";

else if nursery setting is 2:

say "2: Mysterious Ulthar";

else if nursery setting is 3:

say "3: Fantasy World";

else if nursery setting is 4:

say "4: Easter Egg Hunt 2020";

else if nursery setting is 5:

say "5: Kitten Kaboodle";

else if nursery setting is 6:

say "6: Hellish Dungeon".

Instead of entering leo0portal, try going north.

Instead of going north in Cramped Lab:

if the nursery setting is 1:

now the player is in Veldt;

if the nursery setting is 2:

now the player is in Hamlet;

if the nursery setting is 3:

now the player is in Fantasy World;

if the nursery setting is 4:

now the player is in Room5;

if the nursery setting is 5:

now the player is in Ship's Cabin;

if the nursery setting is 6:

now the player is in Dark Dungeon.

Hamlet is a room. The printed name is "Outside the Hamlet". The description is "You're just outside of a small hamlet that lies to the north, across a small stream crossed by a rickety wooden bridge. From what you can tell, the place is abandoned; all the constructions are in a state of utter disrepair."

Instead of going north in Hamlet:

say "You bump your face against an invisible wall of force."

Instead of swimming when the player is in Hamlet:

say "You don't need to swim across. The bridge is still safe to use."

A leo2portal shimmering portal is an open unopenable door. It is fixed in place. It is south of Hamlet. Through it is Cramped Lab. The printed name is "shimmering portal". The description of leo2portal is "It's a kind of weird portal of shimmering light. On the other side you can make out some faint shapes, but nothing too clear."

Instead of exiting in Hamlet, try going south.

Fantasy World is a room. The description is "You find yourself in a strange room surrounded by a swirling mist of colors. Blue, Yellow, a touch of gold..."

A speckled egg is an important thing in Fantasy World. The initial appearance is "A speckled egg is inexplicably floating in the mist." The description is "It's an ordinary speckled hen's egg, perhaps a bit larger than usual." The alter-ego is the Silver egg.

A leo3portal shimmering portal is an open unopenable door. It is fixed in place. It is south of Fantasy World. Through it is Cramped Lab. The printed name is "shimmering portal". The description of leo3portal is "It's a kind of weird portal of shimmering light. On the other side you can make out some faint shapes, but nothing too clear."

Instead of exiting in Fantasy World, try going south.

Ship's Cabin is a room. The description is "You're in a small ship's cabin that's swaying gently from side to side, but everything looks flat and simplified, like in a Tom and Jerry cartoon. The cabin door, hammock, porthole, and footlocker are all just painted images on the wall."

A leo5portal shimmering portal is an open unopenable door. It is fixed in place. It is south of Ship's Cabin. Through it is Cramped Lab. The printed name is "shimmering portal". The description of leo5portal is "It's a kind of weird portal of shimmering light. On the other side you can make out some faint shapes, but nothing too clear."

Instead of exiting in Ship's Cabin, try going south.

A burlap sack is a closed openable important container in Ship's Cabin. The initial appearance is "An overstuffed burlap sack on the floor is the only real thing in here." The alter-ego is the burlap sock.

An Ebony egg is an easter-egg in the burlap sack. The description is "This egg is painted a dark black-brown Ebony color with a fake wood grain pattern that you assume was applied with a toothbrush. The number '5' is stamped on one end."

Instead of opening the burlap sack for the first time:

now the burlap sack is open;

now the initial appearance of the burlap sack is "A burlap sack is on the floor.";

say "ROARRRR!!! In a panic, you ";

if the player carries the burlap sack:

now the burlap sack is in the location of the player;

say "drop ";

else:

say "back away from ";

say "the sack as a very angry lion emerges from it, followed by the rest of his pride in the most hideous cacophony of screeches, yowls, growls, and roars you've ever heard. After a dozen or so lions have all but trampled you in their haste to escape the sack, they suddenly fall apart into showers of twinkling pixels that quickly melt away, Oh, Scotty, I don't feel so good.";

Every turn when the player can see the burlap sack:

if the number of important things in the sack is greater than 0:

now the burlap sack is important;

else:

now the burlap sack is unimportant.

Dark Dungeon is a room. The description is "You're in a dark dungeon. Black stone walls surround you on all directions, with no visible exit in sight."

Instead of exiting in Dark Dungeon, try going south.

A leo6portal shimmering portal is an open unopenable door. It is fixed in place. It is south of Dark Dungeon. Through it is Cramped Lab. The printed name is "shimmering portal". The description of leo6portal is "It's a kind of weird portal of shimmering light. On the other side you can make out some faint shapes, but nothing too clear."

Room6 is west from Room5. Room6 is clockwise from Room5. Room6 is south from CenterRoom. Room6 is southwest from Room3. Room6 is in Rim-region. The printed name is "6 O'Clock". The description is "You're at the south edge of the Big Lawn. Dirt paths go west, east, and north, and [if arch6 is open]an open archway beckons[else]a closed archway is[end if] to the south."

An arch6 archway is an open unopenable scenery door. It is south from Room6. It is north from Baron's Study. The printed name is "archway". Understand "portcullis" as arch6 when arch6 is closed. The description of arch6 is "[if player is in Baron's Study]The open archway leads north back to the Big Lawn[else if arch6 is open]The open archway leads south into a neglected study[else]The archway is now barred with a portcullis since you have taken everything you need from the Baron's study[end if]."

Before going south from Room6 when arch6 is open:

say "This section is adapted from a location in[line break][bold type]Maiden of the Moonlight[roman type][line break]An Interactive Fiction by Brian P. Dean.";

continue the action.

Every turn when the player is in Room6:

if arch6 is open:

if the number of important things enclosed by Baron's Study is 0 and the Navy egg is not nowhere:

now arch6 is closed;

now arch6 is locked;

say "A portcullis falls down inside the archway, blocking your way back inside the study."

Baron's Study is a room. The printed name is "The Baron's Study". The description is "This room was once the Baron's study. The large desk was once a fine piece of woodwork and so was the matching bookcase located beside it against the east wall. An ornate clock hangs on the west wall. An open archway leads north. [if the round window is open]A round window is located behind the desk in the south wall[else]The round window, located behind the desk in the south wall, has been shuttered[end if]."

A bookcase is an open scenery container in Baron's Study. Understand "books" as bookcase. The description is "Most of the books on the bookcase have been ruined by the passage of time. You search through them all, but [if thick book is in bookcase]the only useful-looking item on the shelf is a thick book[else]you find nothing else useful[end if]."

A thick book is an important thing in the bookcase. The description is "[if thick book is in bookcase]The thick book doesn't even have a title on its spine. You'll have to take it out of the bookcase before you can read it[else]The thick book is bound in dark leather which has been oddly untouched by the passage of time. It bears no title and only by paging through it are you able to uncover its subject matter. It is a lengthy treatise on astrology and the stars above. Little of it seems interesting at the moment, but the information that the sign of [ruling sign] currently rules the heavens does grab your eye[end if]." The alter-ego is the thin book.

Instead of taking the thick book for the first time:

now the player is carrying the thick book;

now the small piece of paper is in Baron's Study;

say "When you pull the book off the shelf, a piece of paper that was apparently serving as a bookmark goes fluttering to the floor."

A small piece of paper is an important thing. The description is "The small piece of paper contains a curious notation:[paragraph break] 'The key will cause the clock to chime[line break] And open doors at the witching time.'". The alter-ego is the piece of newspaper.

A large desk is a scenery supporter in Baron's Study. The description is "The desk is coated with a thick layer of dust. It was once an expensive piece of woodworking, but it has been ruined by the passage of time."

An ornate clock is scenery in Baron's Study. The description is "The clock's case is heavily carved with strange dancing figures. The dial is marked with various astrological signs and symbols. There is also a keyhole [if the moon key is in the keyhole]with a key inside it [end if]on the dial. The minute hand is pointing to [numeric setting of the minute hand] and the hour hand is set to [numeric setting of the hour hand]."

A keyhole is an open container. It is part of the ornate clock. The printed name is "keyhole".

Before inserting something into the keyhole:

if the noun is not the moon key:

say "[The noun] doesn't fit into the keyhole." instead.

A minute hand is a clock-hand. It is part of the ornate clock. The numeric setting of the minute hand is 8. The description is "The minute hand is set to [numeric setting of the minute hand]."

An hour hand is a clock-hand. It is part of the ornate clock. The numeric setting of the hour hand is 6. The description is "The hour hand is set to [numeric setting of the hour hand]."

[The moon key was originally found downstairs. This time, we find it when we close the shutters for the first time.]

A moon key is an important thing. The description is "The small key for the clock has an elaborately carved head that resembles a full moon ringed by strange symbols." The alter-ego is the sun key.

Instead of turning the moon key when the moon key is in the keyhole:

if the numeric setting of the minute hand is 12 and the numeric setting of the hour hand is 12 and the Navy egg is nowhere:

now the Navy egg is in Baron's Study;

now the moon key is unimportant;

now the small piece of paper is unimportant;

say "There is a creaking groan from inside the clock. The base of the clock opens up like a door and a Navy egg rolls out before the hidden door closes again.";

else:

say "You give the key a turn. Immediately, there is a loud clanging from inside the clock someplace."

A round window is scenery in Baron's Study. Understand "shutters" as the round window. The round window can be open. The round window is open. The round window can be openable. The round window is openable. The description is "[if the round window is open]The round window is equipped with a small pair of shutters. Looking out the window, you can see nothing but the leaves on the trees outside[else]The shutters are closed[end if]."

Check closing the round window:

if the round window is closed:

instead say "The round window is already shuttered."

Carry out closing the round window:

now the round window is closed.

Report closing the round window:

if the moon key is nowhere and the sun key is nowhere:

now the moon key is in Baron's Study;

say "You close the shutters. But you must have dislodged something: you hear the tinkle of something falling to the floor." instead;

else:

say "You close the shutters." instead.

Check opening the round window:

if the round window is open:

instead say "The round window is already unshuttered."

Carry out opening the round window:

now the round window is open.

Report opening the round window:

say "You open the shutters." instead.

Every turn when the player is in the Baron's Study:

if the maiden is not in the Baron's Study and the round window is open:

if a random chance of one in two succeeds:

now the maiden is in the Baron's Study.

A maiden is a proper-named woman in Baron's Study. The printed name is "The Maiden of the Moonlight". Understand "moonlight", "maiden of moonlight", or "maiden of the moonlight" as the maiden. The description is "The Maiden floats above the floor, surrounded by a beam of moonlight. She never leaves its confines, as if she can't manifest here without it. She is calling out something, but her words have no sound." The initial appearance is "The ghostly form of the Maiden of the Moonlight drifts through the room."

Instead of asking the maiden about:

say "The Maiden doesn't seem to notice you."

Instead of touching the maiden:

say "The Maiden has no physical substance."

Instead of listening to the maiden:

say "She is calling out something, but her words have no sound."

Instead of attacking the maiden:

say "The ghostly form of the Maiden offers no resistance. She doesn't even seem to notice your attack."

Every turn when the player can see the maiden:

if the round window is closed:

now the maiden is nowhere;

say "The Maiden slowly fades from view and is gone.";

else:

say "The Maiden wanders silently through the room."

A Navy egg is an easter-egg. The description is "This Easter egg has been dyed a deep blue color that is indisputably Navy. It has a small number '6' stamped on one end."

Instead of taking the Navy egg for the first time:

if the player carries the basket:

now the Navy egg is in the basket;

else:

now the player carries the Navy egg;

say "You pick up the Navy egg[if player carries the basket] and put it in your basket[end if].".

Room7 is west from Room6. Room7 is clockwise from Room6. Room7 is in Rim-region. The printed name is "7 O'Clock". The description is "You're at the south-by-southwest edge of the Big Lawn. Dirt paths go northwest and east, and [if arch7 is open]an open archway beckons[else]a closed archway is[end if] to the south."

An arch7 archway is an open unopenable scenery door. It is south from Room7 and north from InsideCave. The printed name is "archway". Understand "portcullis" as arch7 when arch7 is closed. The description of arch7 is "[if player is in InsideCave]The open archway leads north back to the Big Lawn[else if arch7 is open]The open archway leads south into a shallow cave[else]The archway is now barred with a portcullis since you have taken everything you need from that cave[end if]."

Before going south from Room7 when arch7 is open:

say "This section is adapted from a location in[line break][bold type]BALANCES[roman type][line break]An Interactive Short Story by Graham Nelson.";

continue the action.

Every turn when the player is in Room7:

if arch7 is open:

if the number of important things enclosed by InsideCave is 0:

now arch7 is closed;

now arch7 is locked;

say "A portcullis falls down inside the archway, blocking your way back inside the cave."

InsideCave is a room. The printed name is "Inside Cave". The description is "A wide but shallow cave not far inside the hill. There is no obvious exit, except for the way you came in."

Instead of going outside from InsideCave, try going north.

Instead of going nowhere from InsideCave, say "The only way is back 'out' through the archway."

Before going north from InsideCave:

if coins are not secure:

instead say "Something bars your way, and you hear the scales jangling militantly. You were trying to steal its coins!";

else if tilt of the scales is not 0:

instead say "Something bars your way, and you hear the scales jangle slightly with energy."

[After taking something when the location is InsideCave:

if the holder of the noun is a scale-pan:

say "Taken from [the holder of the noun]."]

A featureless white cube is an important thing in InsideCave. The initial appearance is "Balanced on a rock formation is a featureless white cube." The description is "A perfect white cube, four inches on a side." The alter-ego is the featureless black cube.

A pair of scales is a supporter in InsideCave. It is fixed in place. Understand "pans" as the scales. The initial appearance is "A fair-sized pair of scales hangs from a bracket in the cave wall. [balance-summary]."

The scales have a number called tilt. The tilt of the scales is 0.

Before doing something with the scales:

instead say "There are left and right hand pans, which you should refer to individually."

Before putting something on the scales:

instead say "There are left and right hand pans, which you should refer to individually."

To say balance-summary:

if the tilt of the scales is 0:

say "The scales are balanced";

else if the tilt of the scales is 1:

say "The left-hand side is higher";

else:

say "The right-hand side is higher".

To decide which number is the weight of (X - a thing):

if X is a bronze-coin:

decide on 2;

if X is an easter-egg or X is the featureless white cube or X is the featureless black cube:

decide on 7;

decide on 3.

To decide if coins are not secure:

let X be the number of balance-coins on the right pan;

let Y be the number of balance-coins on the left pan;

if X plus Y is 8:

decide no;

else:

decide yes.

A right pan is a scale-pan in InsideCave. Five gold-coins are on the right pan.

A left pan is a scale-pan in InsideCave. One bronze-coin and two gold-coins are on the left pan.

A Teal egg is an easter-egg on the left pan. The description is "This egg is a very pleasant blue-green color that you recognize as Teal. Such a calming color that's hard to describe but you know it when you see it. You note that the number '7' has been stamped at one end of the Teal egg."

To decide which number is the calculated tilt:

let L be 0;

let R be 0;

repeat with X running through things on the left pan:

increase L by the weight of X;

repeat with Y running through things on the right pan:

increase R by the weight of Y;

if L is R:

decide on 0;

else if L is less than R:

decide on 1;

else:

decide on -1.

Every turn when the player is in InsideCave:

let N be the calculated tilt;

if the tilt of the scales is not N:

now the tilt of the scales is N;

if N is 0:

say "The scales come into balance.";

else if N is 1:

say "The left pan rises up.";

else:

say "The right pan rises up."

Every turn when the player is in InsideCave:

if the featureless white cube is on a scale-pan or the featureless black cube is on a scale-pan:

now the featureless white cube is unimportant;

now the featureless black cube is unimportant;

else:

now the featureless white cube is important;

now the featureless black cube is important.

Room8 is northwest from Room7. Room8 is clockwise from Room7. Room8 is west from Room4. Room8 is in Rim-region. The printed name is "8 O'Clock". The description is "You're at the west-by-southwest edge of the Big Lawn. Dirt paths go north and southeast, and [if arch8 is open]an open archway beckons[else]a closed archway is[end if] to the west."

An arch8 archway is an open unopenable scenery door. It is west from Room8 and east of Castle Moat. The printed name is "archway". Understand "portcullis" as arch8 when arch8 is closed. The description of arch8 is "[if player is in Castle Moat]The open archway leads east back to the Big Lawn[else if arch8 is open]The open archway leads west to a castle moat[else]The archway is now barred with a portcullis since you have taken everything you need from ye olde adventurous castle[end if]."

Every turn when the player is in Room8:

if arch8 is open:

if the number of important things in Scorp-Region is 0:

now arch8 is closed;

now arch8 is locked;

say "A portcullis falls down inside the archway, blocking your way back to the scorpion-infested moat."

Scorp-Region is a region. Castle Moat, Stinky Tunnel, and Cul-de-Sac are in Scorp-Region.

Before going west from Room8 when arch8 is open:

say "This section is adapted from[line break][bold type]The Homework of Little Carl Gauss - IntroComp04 Preview Version[roman type][line break]A dimension-traveling adventure with sound, no mazes, no darkness, and a bagful of cats! By Stefano Gaburri.";

continue the action.

Castle Moat is a room. The printed name is "In The Moat of Ye Olde Castle". The description is "You find yourself knee-deep in filthy muck, in the moat of an ancient castle. It extends to the north, and you can see it writhing with the most horrendous scorpions. To the west there's [if iron grate is found]an iron grate in [end if]the high mud-covered castle wall. And the archway out of here is to the east."

Instead of going north in Castle Moat:

say "You cannot. The water to the south is filled with nasty scorpions!"

A filthy rag is an important thing in Castle Moat. The description is "It's a simple old, filthy rag, used to sweep the spaceship floors. Feeling like doing some scrubbing, boy? I want to see 'em shine!" The initial appearance is "A filthy rag has been discarded here by a spaceship janitor." The alter-ego is the clean rag.

A muddy castle wall is scenery in Castle Moat.

Instead of rubbing the muddy castle wall:

if the player is carrying the filthy rag or the player is carrying the clean rag:

if the player is carrying the clean rag:

now the player is carrying the filthy rag;

now the clean rag is nowhere;

if the iron grate is unfound:

now the iron grate is found;

now the filthy rag is unimportant;

now the clean rag is unimportant;

say "You clean the mud from the wall with the rag: you have uncovered a grate, bravo!";

else:

say "You really are a dedicated spaceship-boy, fighting dirt wherever you encounter it. Further cleaning of the wall, however, does not reveal anything exciting.";

else:

say "You cannot clean the muddy wall with your bare hands!"

Some muck is scenery in Castle Moat. Understand "mud" as the muck. The description is "The mud is, well, muddy. It's about two feet deep. Even the external wall of the castle is covered with it up to about your height."

Instead of rubbing the muck, try rubbing the muddy castle wall.

An iron grate is a closed openable scenery door. It is west of Castle Moat and east of Stinky Tunnel. The description is "A simple iron grate: through its bars you can see a tunnel going westward."

The iron grate can be found or unfound. The iron grate is unfound.

Instead of going west in Castle Moat when the iron grate is unfound:

say "You smack your face against the muddy castle wall."

Instead of doing anything with the iron grate when the iron grate is unfound:

say "You can't see any such thing."

Some scorpions are scenery animals in Castle Moat. The description is "They are rare amphibian eviscerator scorpions. Extremely dangerous."

Instead of attacking the scorpions:

say "No way, the scorpions would eviscerate you with laughable ease! Your only hope is to get out of here ASAP!".

Instead of touching the scorpions:

say "Don't be silly."

Instead of smelling the scorpions:

say "You don't dare approach the monsters close enough to smell them, but you're sure they stink like hell."

Instead of giving something to the scorpions:

say "The only thing you want to give these scorpions is a barrel full of poisoned rats and you're fresh out."

Instead of swimming when the player is in Castle Moat:

try going north.

Stinky Tunnel is a room. The description is "This is a low, dark, east-west tunnel in the castle wall."

Cul-de-sac is west from Stinky Tunnel. The description is "The tunnel ends here in a cul-de-sac. In the dim light, you can barely see a wall that impedes further westward movement."

An Amber egg is an easter-egg in Cul-de-sac. The description is "This egg is a study in brown-yellow tones highly suggestive of Amber. On one side, a faintly-sketched outline of an insect has been painted. Maybe a wasp? The detail is exquisite. The number '8' has been stamped on one end."

Instead of taking the Amber egg when the Amber egg is in Cul-de-sac and the player carries the basket:

now the Amber egg is in the basket;

say "Taken. You put the Amber egg into your basket."

[We're gonna use the Cragne Family Plot scene where we bail out the grave with an urn, then grab a muddy clump out of the grave. The rain will wash the mud off and reveal the Umber egg. Yay?]

Room11 is northeast from Room10. Room11 is clockwise from Room10. Room11 is west from Room12. Room11 is counterclockwise from Room12. Room11 is north from Room7. Room11 is in Rim-region. The printed name is "11 O'Clock". The description is "You're at the north-by-northwest edge of the Big Lawn. Dirt paths go east and southwest, and [if arch11 is open]an open archway beckons[else]a closed archway is[end if] to the north."

An arch11 archway is an open unopenable scenery door. It is north from Room11 and south from Cragne Family Plot. The printed name is "archway". Understand "portcullis" as arch11 when arch11 is closed. The description of arch11 is "[if the player is in Cragne Family Plot]The open archway leads south back to the Big Lawn[else if arch11 is open]The open archway leads north onto a graveyard[else]The archway is now barred with a portcullis since you have taken everything you need from the Cragne family[end if]."

Before going north from Room11 when arch11 is open:

say "This section is based on Cragne Family Plot by Mark Britton in[line break][bold type]Cragne Manor[roman type][line break]An Anchorhead tribute by various authors.";

continue the action.

Aqua-Region is a region. Cragne Family Plot and Aqua-Grave are in Aqua-Region.

Every turn when the player is in Room11:

if arch11 is open:

if the number of important things in Aqua-Region is 0 and the Umber egg is not nowhere:

now arch11 is closed;

now arch11 is locked;

say "A portcullis falls down inside the archway, blocking your way back to the lagoon."

Room13 is a room. The printed name is "Gargantuan Gazebo". The description is "The Big Lawn has been replaced with a gargantuan gazebo of equal size. The grass is now marble, flowerbeds, furniture, exotic birds, and more, like an entire mansion that took the open concept way too far. Outside the gazebo, you see nothing but sky and clouds. The twelve archways are now pillars that hold up a domed roof of glass and latticework. Floating in the middle of the dome is the solar system, and it looks real, not a model. And unbelievably, the centerpiece and focal point of this extravagant paradise is the pedestal with your straw basket of Easter eggs on top.[if unvisited][paragraph break]What just happened? Did you get teleported here? Or are you still in the Big Lawn -- maybe the gazebo is an illusion? Or was the lawn an illusion and you were here in the gazebo all along? You're so confused.[end if][paragraph break]A few feet away, your host, a tall muscular man wearing a toga and bunny slippers, smiles warmly at you. [if unvisited]Using your keen observational skills, you note that he[else]He[end if] has chosen to accessorize his outfit with a large boa constrictor draped around his neck[if unvisited] which he carries with all the aplomb of a Vegas showgirl[end if]."

Instead of taking the basket when the player is in Room13:

say "It doesn't budge. Looks like the basket is going to stay where it is."

Instead of taking an easter-egg when the player is in Room13:

say "The Easter eggs are now fixed in their places and can no longer be moved."

A glass dome is scenery in Room13. Understand "lattice", "latticework" as the glass dome.

A solar system is scenery in Room13. Understand "planets" as the solar system. The description is "It doesn't make any sense. At this apparent distance, you shouldn't be able to see any of the individual planets, but somehow, you do. You can even see where the orbits are. It can't be real. It has to be an illusion. But what sort of trick is it?"

A sun13 sun is scenery in Room13. The printed name is "sun". The description is "You know you shouldn't stare at the sun, but when you're looking at it from outside the solar system, it's just not as bright as it would be from Earth."

Some pillars are scenery in Room13. The description is "Apart from their gigantic size, the gazebo's twelve pillars look like normal Greco-Roman pillars."

Some clouds are scenery in Room13. Understand "sky" as the clouds. The description is "The sky and clouds look perfectly normal and untroubled. You're just not used to seeing them at a such a close horizon."

A marble floor is scenery in Room13. Understand "tiles" as the marble floor. The description is "Where the floor isn't covered up by carpet lanes and rugs and furniture and whatnot, you can see that the floor is just made of square tiles. White square marble tiles. It's only after staring at them for a minute that you notice they dimly glow much like the Big Lawn's grass did. It's very subtle."

Some flowerbeds are scenery in Room13. Understand "flowers","plants" as the flowerbeds. The description is "Scattered around the gazebo are little terraced areas for flowerbeds. Each individual flowerbed is a delight, and each is growing a different set of flowers and other plants. But, as a group, they seem to have nothing in common with each other: not size, not shape, not materials, and not placement."

Some furniture is scenery in Room13. The description is "All the basic types of furniture seem to be represented here, but everything's so haphazardly placed. And you swear it's moving into new configurations when you're not looking directly at it. How is it doing that?"

Some exotic birds are scenery animals in Room13. Understand "parrots", "toucans", "flamingoes", "robins", "peacocks", "owls" as the exotic birds. The description is "There's quite the variety. You recognize parrots, toucans, flamingoes, robins, peacocks, and owls, but there's many others you don't. They have free rein of the place, and discreetly move or fly away if you get too close."

Some plovers are scenery animals in Room13. Understand "plover" as the plovers.

The description is "Why, yes, there are plovers here too! Sorry I forgot to mention them. They're a type of Egyptian quail, I think. Oh, and look! One of them has a plover's egg!"

After examining the plovers:

now the plover's egg is in Room13;

continue the action.

[Careful. We don't want a random "x egg" to reveal this egg until it's been found.]

A plover's egg is scenery. The description is "The plover's egg is as large as an emerald. On the shell, there's a message: 'The Easter eggs spell out the snake's name.'"

Instead of taking the plover's egg:

say "You don't really need the plover's egg. Just look at it."

A host is a scenery man in Room13. Understand "host", "man", "muscular man", "god", "ophiuchus" as the host. The indefinite article is "your". The description is "You already noted the man's muscles, snake, toga, and bunny slippers. His face is craggy, what you might call 'rugged good-looks'. And he appears amused, mostly, with a bit of tension underneath?. Is that's excitement or worry or something else altogether?"

The host is wearing a toga. The description of the toga is "It's clean, black, opaque, and decorated with white stars. It seems togas can be quite handsome if you're not limited to using a frat boy's bedsheet and safety pins."

The host is wearing bunny slippers. The description of the bunny slippers is "[The host]'s bunny slippers are baby blue and fuzzy. The toe ends have cartoon bunny faces with long ears that flop around, and the heels have cottontails. They look very ridiculous, very cozy, and you want a pair of your own. But maybe in a different color."

The host is carrying a large boa constrictor. Understand "pet", "snake", "serpent" as the boa constrictor. The description of the boa constrictor is "It's a large cream and brown snake. You estimate it to be six or seven feet long. While it's constantly writhing about, it seems quite content to be held by your host, at least at the moment."

Final Puzzle is a scene. Final Puzzle begins when the player is in Room13.

When Final Puzzle begins:

say "'Congratulations, adventurer, on your victory! I see you've found all [italic type]twelve[roman type], ha ha, of my Easter eggs and returned them to me. Thank you! I hope you had as much fun finding them as I did hiding them. Not too challenging for a seasoned adventurer like you, was it? And it is now my pleasure to give you a reward. But how [italic type]large[roman type] a reward, hmm? I do believe a final puzzle is in order, [italic type]mm[roman type]-yes.[paragraph break]'Now I'm sure you've noticed my pet snake. He's not at all tame with strangers, but don't worry. I know how to handle him. All I want [italic type]you[roman type] to do is GUESS his name. I gave him one of [italic type]my[roman type] old names that I wasn't using any more.[paragraph break]'So. Feel free to look around. Maybe I've left a clue somewhere. I'll give you three guesses, and I'll base your reward on your best guess."

The high-score is a number that varies. The high-score is 1.

The guess-count is a number that varies. The guess-count is 0.

Guessing is an action applying to one topic. Understand "guess '[text]'" or "guess [text]" as guessing.

Understand "guess" as a mistake ("You need to guess a name. For example: GUESS FRED.").

To note a (N - a number) point guess:

increase the guess-count by 1;

if N is greater than the high-score:

now the high-score is N.

Before guessing:

if the player is not in Room13:

instead say "No one's asked you to guess anything yet."

Instead of guessing "jesus":

note a 2 point guess;

say "'Oh, ha ha ha! No, it's not [']Jesus[']. Thanks for the laugh, but I'll rate that guess a 2.'"

Instead of guessing "bunny":

note a 3 point guess;

say "'[']Bunny[']? Hell, no. I'll rate that guess a 3.'"

Instead of guessing "easter bunny":

note a 3 point guess;

say "'[']Easter Bunny[']? Hell, no. I'll rate that guess a 3.'"

Instead of guessing "joshua":

note a 4 point guess;

say "'What? Where did you get [']Joshua['] from?' Your host stops to think for a second. 'Oh! I get it now. That's inspired but very wrong. I'll rate that guess a 4, though.'"

Instead of guessing "easter":

note a 4 point guess;

say "'[']Easter[']? Nope. I'll rate that guess a 4.'"

Instead of guessing "egg":

note a 4 point guess;

say "'[']Egg[']? Nope. I'll rate that guess a 4.'"

Instead of guessing "eggs":

note a 4 point guess;

say "'[']Eggs[']? Nope. I'll rate that guess a 4.'"

Instead of guessing "slytherin":

note a 5 point guess;

say "'Definitely not [']Slytherin[']. I'm a lot older than anyone in Harry Potter. But I'll rate that guess a 5 for the snake theme.'"

Instead of guessing "voldemort":

note a 5 point guess;

say "'Definitely not [']Voldemort[']. I'm a lot older than anyone in Harry Potter. But I'll rate that guess a 5 for the snake theme.'"

Instead of guessing "salazar":

note a 5 point guess;

say "'Definitely not [']Salazar[']. I'm a lot older than anyone in Harry Potter. But I'll rate that guess a 5 for the snake theme.'"

Instead of guessing "nagini":

note a 5 point guess;

say "'Definitely not [']Nagini[']. I'm a lot older than anyone in Harry Potter. But I'll rate that guess a 5 for the snake theme.'"

Instead of guessing "patrick":

note a 5 point guess;

say "'[']Patrick[']? Oh, like in Saint Patrick? That's not really close at all. But I'll rate that guess a 5 for the snake theme.'"

Instead of guessing "medusa":

note a 5 point guess;

say "'[']Medusa[']? I'll rate that guess a 5 for the snake theme. I want to give an extra point for the Greek connection, but you lose that point because Medusa is a woman's name."

Instead of guessing "gorgon":

note a 6 point guess;

say "'[']Gorgon[']? I'll rate that guess a 6 for the snake theme.'"

Instead of guessing "snake":

note a 6 point guess;

say "'[']Snake[']? Really? On a scale of 1 to 13, I'll rate that guess a 6.'"

Instead of guessing "boa":

note a 6 point guess;

say "'[']Boa[']? Really? On a scale of 1 to 13, I'll rate that guess a 6.'"

Instead of guessing "constrictor":

note a 6 point guess;

say "'[']Constrictor[']? Really? On a scale of 1 to 13, I'll rate that guess a 6.'"

Instead of guessing "zodiac":

note a 7 point guess;

say "'[']Zodiac[']? No, that's not it, but on a scale of 1 to 13, I'll rate that guess a 7.'"

Instead of guessing "serpent":

note a 7 point guess;

say "He looks amused. '[']Serpent['] is such an uninspired guess, but on a scale of 1 to 13, I'll rate that guess a high 7.'"

Instead of guessing "serpens":

note a 8 point guess;

say "'Hm. [']Serpens['], eh? Interesting. Well, I can be generous. On a scale of 1 to 13, I'll rate that guess a low 8.'"

Instead of guessing "serpentis":

note a 8 point guess;

say "'Hm. [']Serpentis['], eh? Interesting. Well, I can be generous. On a scale of 1 to 13, I'll rate that guess a high 8.'"

Instead of guessing "serpent-charmer":

note a 8 point guess;

say "'[']Serpent-charmer[']? What an odd, interesting guess. On a scale of 1 to 13, I'll rate that guess an 8.'"

Instead of guessing "ophiuchus":

note a 9 point guess;

say "'[']Ophiuchus['] is [italic type]my[roman type] current name, not my old name. But you're on the right track. On a scale of 1 to 13, I'll rate that guess a 9.'"

Instead of guessing "serpent-bearer":

note a 9 point guess;

say "'[']Serpent-bearer['] is my [italic type]title[roman type], not my name. But it's still a good enough guess that on a scale of 1 to 13, I'll rate that guess a 9.'"

Instead of guessing "ophiulchus":

note a 10 point guess;

say "'[']Ophiulchus['] is a variant of my current name. On a scale of 1 to 13, I'll rate that guess a 10.'"

Instead of guessing "ophiulcus":

note a 10 point guess;

say "'[']Ophiulcus['] is a variant of my current name. On a scale of 1 to 13, I'll rate that guess a 10.'"

Instead of guessing "ophiultus":

note a 10 point guess;

say "'[']Ophiultus['] is a variant of my current name. On a scale of 1 to 13, I'll rate that guess a 10.'"

Instead of guessing "ophiuculus":

note a 10 point guess;

say "'[']Ophiuculus['] is a variant of my current name. On a scale of 1 to 13, I'll rate that guess a 10.'"

Instead of guessing "ophiulculus":

note a 10 point guess;

say "'[']Ophiulculus['] is a variant of my current name. On a scale of 1 to 13, I'll rate that guess a 10.'"

Instead of guessing "anguifer":

note a 11 point guess;

say "'[']Anguifer['] is indeed one of my old names, but not the one I'm looking for. On a scale of 1 to 13, I'll rate that guess a 11.'"

Instead of guessing "anguiger":

note a 11 point guess;

say "'[']Anguiger['] is indeed one of my old names, but not the one I'm looking for. On a scale of 1 to 13, I'll rate that guess a 11.'"

Instead of guessing "anguitenens":

note a 11 point guess;

say "'[']Anguitenens['] is indeed one of my old names, but not the one I'm looking for. On a scale of 1 to 13, I'll rate that guess a 11.'"

Instead of guessing "serpentiger":

note a 11 point guess;

say "'[']Serpentiger['] is indeed one of my old names, but not the one I'm looking for. On a scale of 1 to 13, I'll rate that guess a 11.'"

Instead of guessing "serpentis lator":

note a 11 point guess;

say "'[']Serpentis Lator['] is indeed one of my old names, but not the one I'm looking for. On a scale of 1 to 13, I'll rate that guess a 11.'"

Instead of guessing "serpentis praeses":

note a 11 point guess;

say "'[']Serpentis Praeses['] is indeed one of my old names, but not the one I'm looking for. On a scale of 1 to 13, I'll rate that guess a 11.'"

Instead of guessing "serpentaire":

note a 12 point guess;

say "'[']Serpentaire['] is so maddeningly close to correct. On a scale of 1 to 13, I'll rate that guess a high 12.'"

Instead of guessing "serpentinarius":

note a 12 point guess;

say "'[']Serpentinarius['] is so extremely close to correct. On a scale of 1 to 13, I'll rate that guess a high 12.'"

Instead of guessing "serpentarius":

note a 13 point guess;

say "'[']Serpentarius['] is correct! On a scale of 1 to 13, I'll rate that guess a perfect 13!'"

Report guessing:

note a 1 point guess;

say "'Sorry, that isn't even close. On a scale of 1 to 13, I'll rate that guess a 1.'"

Every turn when the player is in Room13:

if the high-score is 13:

say "'An amazing job. It's now time to give you your reward. To begin with, you have won all twelve of the eggs you found. Each egg contains a small wish, nothing too extravagant. Gold, jewels, health, luck, that sort of thing. Break them when needed to gain their blessings.[paragraph break]'Also, you fully deserve this thirteenth egg, a true Orichalcum egg decorated with an ouroboros as a girdle. Keep it in remembrance of me.[paragraph break]'Furthermore, as I'm sure you've guessed, I am Ophiuchus, the serpent-bearer, and I am quite fond of all things serpentine, including puzzles! So my best gift to you is my friendship and the promise of more puzzles.[paragraph break]'Here is my amulet. Once every Spring, hold its stone and call my name. I will hear you and transport you to my demesne and we shall find another puzzle for you to solve.'";

end the story finally saying "You won thirteen eggs and the top prize";

else if the guess-count is 3:

say "'That's your three guesses. It's now time to give you your reward. [if high-score is greater than 6]To begin with, you[else]You[end if] have won your choice of [high-score in words] of the eggs you found. Each egg contains a small wish, nothing too extravagant. Gold, jewels, health, luck, that sort of thing. Break [if high-score is 1]it[else]them[end if] when needed to gain [if high-score is 1]its blessing[else]their blessings[end if]. ";

if the high-score is greater than 9:

say "[paragraph break]'I also award you a magic golden circlet in the shape of a serpent; wear it when you need more cunning. Good luck with your future adventures.'";

end the story finally saying "You won [high-score in words] eggs and the runner-up prize";

else if the high-score is greater than 6:

say "[paragraph break]'I also award you a magic brass belt in the shape of a serpent; wear it when you need more strength. Good luck with your future adventures.'";

end the story finally saying "You won [high-score in words] eggs and the second runner-up prize";

else if the high-score is greater than 1:

say " Good luck with your future adventures.'";

end the story finally saying "You won [high-score in words] eggs";

else:

say " Good bye.'";

end the story finally saying "You won one egg".

[Strip any quote marks from the player's command so GUESS "SNAKE" is understood as GUESS SNAKE.]

After reading a command:

let T be "[the player's command]";

replace the regular expression "'" in T with "";

change the text of the player's command to T.

CenterRoom is southwest from Room1.

CenterRoom is southwest from Room2.

CenterRoom is northwest from Room4.

CenterRoom is northwest from Room5.

CenterRoom is northeast from Room7.

CenterRoom is northeast from Room8.

CenterRoom is southeast from Room10.

CenterRoom is southeast from Room11.

[NE from CenterRoom is either Room1 or Room2.]

Instead of going northeast from CenterRoom:

if arch1 is open and arch2 is closed:

say "You head across the lawn to the open archway at 1 O'Clock.";

now the player is in Room1;

else if arch1 is closed and arch2 is open:

say "You head across the lawn to the open archway at 2 O'Clock.";

now the player is in Room2;

else:

say "You head across the lawn to one of two [if arch1 is open]open[else]closed[end if] archways at random.";

if a random chance of 1 in 2 succeeds:

now the player is in Room1;

else:

now the player is in Room2.

[NW from CenterRoom is either Room10 or Room11.]

Instead of going northwest from CenterRoom:

if arch10 is open and arch11 is closed:

say "You head across the lawn to the open archway at 10 O'Clock.";

now the player is in Room10;

else if arch10 is closed and arch11 is open:

say "You head across the lawn to the open archway at 11 O'Clock.";

now the player is in Room11;

else:

say "You head across the lawn to one of two [if arch10 is open]open[else]closed[end if] archways at random.";

if a random chance of 1 in 2 succeeds:

now the player is in Room10;

else:

now the player is in Room11.

[SW from CenterRoom is either Room7 or Room8.]

Instead of going southwest from CenterRoom:

if arch7 is open and arch8 is closed:

say "You head across the lawn to the open archway at 7 O'Clock.";

now the player is in Room7;

else if arch7 is closed and arch8 is open:

say "You head across the lawn to the open archway at 8 O'Clock.";

now the player is in Room8;

else:

say "You head across the lawn to one of two [if arch7 is open]open[else]closed[end if] archways at random.";

if a random chance of 1 in 2 succeeds:

now the player is in Room7;

else:

now the player is in Room8.

[SE from CenterRoom is either Room4 or Room5.]

Instead of going southeast from CenterRoom:

if arch4 is open and arch5 is closed:

say "You head across the lawn to the open archway at 4 O'Clock.";

now the player is in Room4;

else if arch4 is closed and arch5 is open:

say "You head across the lawn to the open archway at 5 O'Clock.";

now the player is in Room5;

else:

say "You head across the lawn to one of two [if arch4 is open]open[else]closed[end if] archways at random.";

if a random chance of 1 in 2 succeeds:

now the player is in Room4;

else:

now the player is in Room5.

[Messages using the paths to and from CenterRoom]

Before going north from CenterRoom:

say "You head up the north path."

Before going west from CenterRoom:

say "You head along the west path."

Before going east from CenterRoom:

say "You head along the east path."

Before going south from CenterRoom:

say "You head down the south path."

Before going north from Room6:

say "You take the path back to the center."

Before going west from Room3:

say "You take the path back to the center."

Before going east from Room9:

say "You take the path back to the center."

Before going south from Room12:

say "You take the path back to the center."

[Messages cutting over the grass back to CenterRoom]

Before going southwest from Room1:

say "You cut across the lawn back down to the center."

Before going southwest from Room2:

say "You cut across the lawn back down to the center."

Before going northwest from Room4:

say "You cut across the lawn back up to the center."

Before going northwest from Room5:

say "You cut across the lawn back up to the center."

Before going northeast from Room7:

say "You cut across the lawn back up to the center."

Before going northeast from Room8:

say "You cut across the lawn back up to the center."

Before going southeast from Room10:

say "You cut across the lawn back down to the center."

Before going southeast from Room11:

say "You cut across the lawn back down to the center."

[Messages taking the big diamond paths between 12, 3, 6, and 9]

Before going southeast from Room12:

say "You cut diagonally across a corner of the lawn."

Before going southwest from Room12:

say "You cut diagonally across a corner of the lawn."

Before going northwest from Room3:

say "You cut diagonally across a corner of the lawn."

Before going southwest from Room3:

say "You cut diagonally across a corner of the lawn."

Before going northwest from Room6:

say "You cut diagonally across a corner of the lawn."

Before going northeast from Room6:

say "You cut diagonally across a corner of the lawn."

Before going northeast from Room9:

say "You cut diagonally across a corner of the lawn."

Before going southeast from Room9:

say "You cut diagonally across a corner of the lawn."

[Messages taking the long vertical paths: 1 to 5, 11 to 7, and vice versa]

Before going south from Room1:

say "You quickly jog down to the other side of the lawn."

Before going south from Room11:

say "You quickly jog down to the other side of the lawn."

Before going north from Room5:

say "You quickly jog up to the other side of the lawn."

Before going north from Room7:

say "You quickly jog up to the other side of the lawn."

[Messages taking the long horizontal paths: 10 to 2, 8 to 4, and vice versa]

Before going west from Room2:

say "You quickly jog across to the other side of the lawn."

Before going west from Room4:

say "You quickly jog across to the other side of the lawn."

Before going east from Room8:

say "You quickly jog across to the other side of the lawn."

Before going east from Room10:

say "You quickly jog across to the other side of the lawn."

A sorting box is a container.

To sort the basket:

now everything in the basket is in the sorting box;

if Sapphire egg is in the sorting box:

now the Sapphire egg is in the basket;

if Umber egg is in the sorting box:

now the Umber egg is in the basket;

if Indigo egg is in the sorting box:

now the Indigo egg is in the basket;

if Ruby egg is in the sorting box:

now the Ruby egg is in the basket;

if Amber egg is in the sorting box:

now the Amber egg is in the basket;

if Teal egg is in the sorting box:

now the Teal egg is in the basket;

if Navy egg is in the sorting box:

now the Navy egg is in the basket;

if Ebony egg is in the sorting box:

now the Ebony egg is in the basket;

if Puce egg is in the sorting box:

now the Puce egg is in the basket;

if Rose egg is in the sorting box:

now the Rose egg is in the basket;

if Emerald egg is in the sorting box:

now the Emerald egg is in the basket;

if Silver egg is in the sorting box:

now the Silver egg is in the basket.

To say ruling sign:

if the player is in Room1 or the player is in Laboratory:

say "Aries";

else if the player is in Room2 or the player is in Taurus-Region:

say "Taurus";

else if the player is in Room3 or the player is in Meditation Room:

say "Gemini";

else if the player is in Room4 or the player is in Cancer-Region:

say "Cancer";

else if the player is in Room5 or the player is in Leo-Region:

say "Leo";

else if the player is in Room6 or the player is in Baron's Study:

say "Virgo";

else if the player is in Room7 or the player is in InsideCave:

say "Libra";

else if the player is in Room8 or the player is in Scorp-Region:

say "Scorpio";

else if the player is in Room9 or the player is in Sag-Region:

say "Sagittarius";

else if the player is in Room10 or the player is in Cap-Region:

say "Capricorn";

else if the player is in Room11 or the player is in Aqua-Region:

say "Aquarius";

else if the player is in Room12 or the player is in Pisces-Region:

say "Pisces";

else:

say "Ophiuchus";

Xyzzying is an action applying to nothing. Understand "xyzzy" as xyzzying.

Instead of xyzzying:

say "Looking for the other kind of Easter eggs, too, eh? Well, there is magic in this game, but XYZZY isn't one of the magic words.".

Plughing is an action applying to nothing. Understand "plugh" as plughing.

Instead of plughing:

say "Looking for the other kind of Easter eggs, too, eh? Well, there is magic in this game, but PLUGH isn't one of the magic words.".

Plovering is an action applying to nothing. Understand "plover" as plovering.

Instead of plovering for the first time:

say "Looking for the other kind of Easter eggs, too, eh? Well, there is magic in this game, but PLOVER isn't one of the magic words. Still, plovers [italic type]do[roman type] have eggs, don't they? Hmmm...[paragraph break]Okay, fine. Here's a secret: there are plovers in the game, somewhere. Go find them.".

Instead of plovering:

say "Looking for the other kind of Easter eggs, too, eh? Well, there is magic in this game, but PLOVER isn't one of the magic words."

         is an action applying to nothing. Understand "        " as         .

Instead of         :

now the player carries the basket;

now eegg-seen is 1;

now every easter-egg is in the basket;

now the player is in CenterRoom;

say "Quick as a bunny, you collect all the eggs! Now [italic type]that's[roman type] Easter magic!".

Test room4 with "e / e / ne / ne / take hat / sw / sw / w / w".

Test room5 with "s / z / z / z / z / z / z / z / z / z / s / set dial to 3 / n / take speckled egg / s / set dial to 5 / n / open sack / take sack / s / set dial to 4 / n".

Test room6 with "s / close shutters / look / take key / x bookcase / take book / take paper / read paper / put key in keyhole / set minute to 12 / set hour to 12 / turn key / take navy egg / n".

Test room7 with "s / take cube / take teal / put cube on left pan / n".

Test room8 with "w / take rag / clean wall / w / w / take amber / e / e / e".

Test room9 with "w / u / s / take bow and arrow / x window / n / d / nock arrow on bow / shoot apple / quivver / w / take ruby / e / e".

Test room10 with "w / take goat / w / w / w".

Test room11 with "n / take urn / bail grave / g / d / dig west / u / s".

Test room12 with "n / e / take bag / w / give popcorn to fish / swim / s".

Test room1 with "n / give speckled egg to ram / s".

Test room2 with "e / e / x bull / take emerald / w / w".

Test room3 with "e / sit / pick 14 / pick 15 / pick 3 / pick 8 / pick 21 / pick 17 / pick 7 / pick 25 / pick 1 / pick 22 / pick 20 / pick 23 / pick 4 / pick 24 / pick 9 / pick 11 / pick 12 / pick 18 / pick 10 / pick 13 / pick 6 / pick 19 / pick 5 / pick 16 / pick 2 / stand / w".

Test finale with "         / put basket on pedestal / guess serpentarius".